在 Clojure 中，如何对元素进行分组？

Question

在 clojure 中，我想聚合这些数据：

(def data [[:morning :pear][:morning :mango][:evening :mango][:evening :pear]])
(group-by first data)
;{:morning [[:morning :pear][:morning :mango]],:evening [[:evening :mango][:evening :pear]]}

我的问题是 :evening 和 :morning 是多余的。 相反，我想创建以下集合：

([:morning (:pear :mango)] [:evening (:mango :pear)])

我想出了：

(for [[moment moment-fruit-vec] (group-by first data)] [moment (map second moment-fruit-vec)])

是否有更惯用解决方案？

Answer 1

我也遇到过类似的分组问题。通常我最终会将 merge-with 或 update-in 插入到某个 seq 处理步骤中：

(apply merge-with list (map (partial apply hash-map) data))

您会得到一个映射，但这只是一个键值对的 seq：

user> (apply merge-with list (map (partial apply hash-map) data))
{:morning (:pear :mango), :evening (:mango :pear)}
user> (seq *1)
([:morning (:pear :mango)] [:evening (:mango :pear)])

但是，如果每个键出现两次，此解决方案只能得到您想要的内容。这可能会更好：

(reduce (fn [map [x y]] (update-in map [x] #(cons y %))) {} data)

这两者都感觉“更实用”，但也感觉有点复杂。不要太快地否定您的解决方案，它很容易理解并且功能足够。

Answer 2

不要太快地关闭 group-by，它已按所需的键聚合您的数据，并且它没有更改数据。任何其他需要矩-果对序列的函数都将接受在 group-by 返回的映射中查找的任何值。

在计算摘要方面，我倾向于使用merge-with，但为此我必须将输入数据转换为一系列映射，并使用所需的键和构造一个“基本映射”空向量作为值。

(let [i-maps (for [[moment fruit] data] {moment fruit})
      base-map (into {} 
                  (for [key (into #{} (map first data))] 
                    [key []]))]
      (apply merge-with conj base-map i-maps))

{:morning [:pear :mango], :evening [:mango :pear]}

Answer 3

思考 @mike t 的答案，我想出了：

(defn agg[x y] (if (coll? x) (cons y x) (list y x)))
(apply merge-with agg (map (partial apply hash-map) data))

当按键出现时，此解决方案也有效data 上的次数超过两次：

 (apply merge-with agg (map (partial apply hash-map) 
     [[:morning :pear][:morning :mango][:evening :mango] [:evening :pear] [:evening :kiwi]]))
;{:morning (:mango :pear), :evening (:kiwi :pear :mango)}

Answer 4

也许只需稍微修改一下标准分组：

(defn my-group-by 
  [fk fv coll]  
  (persistent!
   (reduce
    (fn [ret x]
      (let [k (fk x)]
        (assoc! ret k (conj (get ret k []) (fv x)))))
    (transient {}) coll)))

然后将其用作：

(my-group-by first second data)