从数组 ColdFusion 中删除关联对象

Question

我有一个购物车数组，其中保存购物车中商品的产品信息。部分新增商品与“主商品”一起购买可享受特别折扣。

如果有人添加了一个与特价优惠相关的商品，我会在商品结构中设置一个名为 mainitem 的键，其值为 yes，所有后续特价商品都会关联主项目的键 mainitem 设置为 no 并具有另一个名为 mainitemid 的键（这是 mainitem uid ）。

如果有人删除了主要项目，我需要确保所有相关的特价商品也被删除。这就是我遇到的麻烦，无法完全弄清楚如何找到它们。

我使用 form.itemID 来提供要删除的产品的项目 ID。我需要确保被删除的项目是主要项目；如果是这样，请循环浏览购物车的其余部分，找到任何 mainitemid 等于 form.itemid 的商品并将其删除，然后删除 mainitem 。

mainitem 定义为 session.mycart[i].mainitem maintitenid 定义为 session.mycart[i].mainitemid

<cfloop index="i" from="1" to="#arrayLen(session.mycart)#">

</cfloop>

我需要创建两个循环还是可以用一个循环来完成？我不确定我的条件陈述。

Answer 1

针对 OP 特定问题的解决方案

进行修改以提供更完整的解决方案

<!--- First of all, will need to go 1 to ArrayLen() to find the main item id.  Doesn't matter what order you go here, but main items should be inserted before children so may as well start at the bottom --->
<cfloop index="i" from="1" to="#ArrayLen(session.mycart)#">
    <!--- Is this the main item? --->
    <cfif session.mycart[i].id EQ form.itemID>
        <!--- It's found the item, is it a main item?  We've found the item so entering here to break the loop --->
        <cfif session.mycart[i].mainitem>
            <!--- Go from  ArrayLen() to 1, as if you go 1 to ArrayLen() when deleting you confuse Coldfusion --->
            <cfloop index="j" from="#ArrayLen(session.mycart)#" to="1" step="-1">
                <cfif session.mycart[j].id EQ form.itemID OR session.mycart[j].mainitemid EQ form.itemID>
                    <cfset ArrayDeleteAt(session.mycart,j)>
                </cfif>
            </cfloop>
        </cfif>
        <!--- This loop is done, so break out --->
        <cfbreak>
    </cfif>
</cfloop>

在您的帖子中，您声明您正在从索引 1 循环到索引 ArrayLen(...)。如果您要从数组中删除项目，Coldfusion 有点简单，并没有真正引起注意，因此当您删除 5 元素数组的元素 2 时，数组将变为 4 个元素长（因为您删除了一个元素），并且原来索引 3 的元素现在是索引 2，因此它被遗漏了。

解决这个问题的方法是从最后开始并向后进行。只要您一次最多删除 1 条记录，那么这就是完全有效的，因为它将继续减少当前正在检查的索引，直到减少到 1，这将是第一个元素。

这样，您可以遍历元素 5、4、3、2，删除元素 2，然后它会检查索引 1，索引 1 现在仍然与开始循环时相同，因此不会发生跳过。

关于如何处理这个问题的一些简介

我误读了这个问题，或者在写这篇文章时对其进行了编辑，但下面的内容是适用的，所以仍然将其留在这里

您是否考虑过有特殊的提供项目作为主项目的子项，因为它将整个报价封装在一起，删除父项也会删除子项。我有一个类似的问题，其中项目具有与其关联的选项，并且为了允许观察层次结构，我决定创建与引用数组相结合的树。只是作为一个粗略的例子来展示原理，看看这个

<cfscript>
    // Create a main item structure
    stcMainItem = {
        id = CreateUUID(),
        somekey = somevalue,
        someotherkey = someothervalue,
        cost = 123
    };

    // Create some child item structures, special offers for ex
    stcSpecialOfferItem1 = {
        id = CreateUUID(),
        parent = stcMainItem.id,
        cost = 45
    };

    stcSpecialOfferItem2 = {
        id = CreateUUID(),
        parent = stcMainItem.id,
        cost = 45
    };



    // Each is added to a reference array
    arrItemReference = [];
    arrItemRefernce.add(stcMainItem);
    arrItemRefernce.add(stcSpecialOfferItem1);
    arrItemRefernce.add(stcSpecialOfferItem2);

    // Now you decide to delete the main item and direct parents
    strIDToDelete = stcMainItem.id;
    for (i=ArrayLen(arrItemReference);i>=1;i--) {
        if (
            arrItemReference[i].id == strIDToDelete
            ||
            arrItemReference[i].parent == strIDToDelete
        ) {
            ArrayDeleteAt(arrItemReference,i);
        }
    }
</cfscript>

在我的实际代码中，我通过创建一个 Item.cfc 来完成此操作，其中包含处理上述内容的方法并向上级联树删除孙子等，但是这个原则是合理的。本质上，您拥有允许将项目公开为平面数组以及父项、子项和兄弟项的层次结构的方法。

信息点

顺便说一句，当“数组”和“结构”略有不同时，您可以不断地互换它们，这与 PHP 等语言不同，在 PHP 中，数组用于引用这两个术语。数组包含数字索引从 1 到 n 的值，而结构体是保存与任意键相关的值的对象。但存在差异的原因是它们不是基于相同的基础 java 对象构建的，因此某些适用于其中一个对象的方法不适用于另一个对象。

Answer 2

<cfloop index="i" from="1" to="#arrayLen(session.mycart)#">
    <cfif session.mycart[i].mainitem eq "no" AND session.mycart[i].mainitemid EQ form.itemid>
        <cfset arrayDeleteAt(session.myCart,i) />
        <cfset i = i - 1 /><!--- this is necessary to keep you from running out of the end of the loop --->
    </cfif>
</cfloop>

当然，这还没有经过测试，您可能必须使用它来输入确切的变量名称，但我认为它应该可以帮助您实现这一点。如果我误解了这个问题，请告诉我。

Answer 3

我没有找到一种方法可以在一个循环中完成此操作，因为我将其视为一个两步过程。首先，您必须查看删除的项目 ID 是否是主项目，然后返回数组并删除其余关联项目。

根据需要添加 StructKeyExists()。

<!--- Find Main Item --->
<cfset isMainItem = false />
<cfloop from='1' to='#ArrayLen( Session.MyCart )#' index='item'>
    <cfif Session.MyCart[ item ].ItemID EQ Form.ItemID AND Session.MyCart[ item ].MainItem EQ 'Yes'>
        <cfset isMainItem = true />
        <cfbreak />
    </cfif>
</cfloop>

<cfif isMainItem>
    <!--- Clean up special offer items --->
    <cfloop from='1' to='#ArrayLen( Session.MyCart )#' index='item'>
        <cfif Session.MyCart[ item ].MainItemID EQ Form.ItemID AND Session.MyCart[ item ].MainItem EQ 'No'>
            <cfset ArrayDeleteAt( Sesion.MyCart, Item ) />
            <cfset item-- />
        </cfif>
    </cfloop>
</cfif>