录音正常，播放速度太快

Question

我正在使用以下功能录制麦克风的音频输入：

    private function handleSampleData(p_sampleEvent:SampleDataEvent) :void
    {
        var data :Number;
        while (p_sampleEvent.data.bytesAvailable)
        {
            data = p_sampleEvent.data.readFloat();
            _buffer.writeFloat(data);
            _buffer.writeFloat(data);
        }
    }

这似乎有效。完成录音后，我将录制的数据复制到另一个缓冲区，如下所示：

            _buffer.position = 0;
            _lastRecord = new ByteArray();
            while (_buffer.bytesAvailable)
            {
                _lastRecord.writeFloat(_buffer.readFloat());
            }
            _lastRecord.position = 0;

然后，我对新创建的声音使用 play() 并使用此函数将 _lastRecord 缓冲区提供给它：

    public function handlePlaybackSampleData(p_sampleEvent:SampleDataEvent) :void 
    {
        // Read data until either MAX_SAMPLES or all available samples are reached.
        var i:int = 0;
        var data :Number = 0;
        while( i < 8192 )
        {
            if( _lastRecord.bytesAvailable )
            {
                data = _lastRecord.readFloat();
                p_sampleEvent.data.writeFloat(data);
                i++;
                continue;
            }
            else 
            {
                break;
            }
        }
    }

虽然它基本上有效，但生成的结果播放的声音太快了。 我从一个示例中获取了大部分代码，该示例运行得很好。我发现我的代码与此代码之间没有更重要的区别： http ://labs.makemachine.net/2011/04/record-visualize-save-microphone-input/

不过，音频输出速度太快了。如果我通过添加更多“_buffer.writeFloat(data);”将更多数据放入_buffer中，它会变得更好，当我有12行时，它就是所需的速度。但即便如此，只有当我撞到麦克风时才有帮助。如果我真的说话，这似乎也不够。

但怎么会这样呢？为什么在我从中获取代码的示例中，只有 2 行就足够了？有没有办法确定录制时需要写入缓冲区的数据量？

Answer 1

FlashPlayer 中麦克风的默认采样率为 8 kHz 单声道 - 或者，如果不可用，则使用第一个可用的 11.025 kHz、22.05 kHz 或 44.1 kHz。音频输出始终为 44.1 kHz 立体声。这意味着您获得的样本太少：44.1 / 8 ~= 5.5。

您可以通过将记录采样率设置为 44.1 kHz 来解决此问题：

microphone.rate = 44; // Yes, the API doesn't want the decimals

您还可以将速率保持在 22 或 11，然后在记录时将额外的重复样本写入缓冲区（简单的“上采样”） - 即写入 4 个浮点，而不是2，如果以 22 kHz 录音，8 如果以 11 kHz 录音。

另一件需要注意的事情是，输出样本不是单个浮点数，而是两个浮点数 - 每个通道一个。因此，麦克风将为您提供 8192 个单声道样本，您应该通过将每个样本写入两次来将其应用到两个通道。您现在有 8192 个“立体声”样本。

然而，当您编写输出时，您最多编写 8192 个浮点 (i) - 对应于 4096 个立体声样本。另一半 - 我从你的代码和结果中假设 - 被扔掉了。

最后，您得到的是 8192 个样本的前半部分，其采样率大约比播放采样率低 5.5 倍。这意味着声音的播放速度似乎快了 2*5.5 = 11 倍。

确保将所有样本写入输出，并以 44.1 kHz 记录（或如上所述的上采样），并且应以正确的速度播放。

顺便说一句，event.data.writeBytes 复制缓冲区的速度可能会快很多（假设 - 尚未实际检查）：

_lastRecord = new ByteArray();
_lastRecord.writeBytes(_buffer, 0, _buffer.bytesAvailable);

写入示例数据也是如此:

public function handlePlaybackSampleData(p_sampleEvent:SampleDataEvent) :void 
{
   // Maximum amount of samples we're allowed to write: 8192
   // Copying bytes here, rather than floats, so:
   // 8192 samples * 2 channels * 4 bytes per float = 65536:
   var bytesToCopy:int = Math.min(_lastRecord.bytesAvailable, 65536);

   // Using _lastRecord.position since some of it may have been written on the
   // last call to handlePlaybackSampleData if it had more than 8192 samples:
   p_sampleEvent.data.writeBytes(
      _lastRecord, 
      _lastRecord.position, 
      bytesToCopy
   );
}