“预期声明”在VB脚本中

Question

我是 vbscript 新手。我收到错误

预计在 get_html 处声明

我的代码的底部。我实际上试图为变量 get_html 声明一个值（即一个 url）。我该如何解决这个问题？

Module Module1

Sub Main()

End Sub
Sub get_html(ByVal up_http, ByVal down_http)
    Dim xmlhttp : xmlhttp = CreateObject("msxml2.xmlhttp.3.0")
    xmlhttp.open("get", up_http, False)
    xmlhttp.send()

    Dim fso : fso = CreateObject("scripting.filesystemobject")

    Dim newfile : newfile = fso.createtextfile(down_http, True)
    newfile.write(xmlhttp.responseText)

    newfile.close()

    newfile = Nothing
    xmlhttp = Nothing

End Sub
get_html _"http://www.somwwebsite.com", _"c:\downloads\website.html"

End Module

Answer 1

您可能希望将对 get_html 的调用移至 Main 子例程 (Sub Main()) 内进行调用。例如：

Sub Main()
  get_html _"http://www.somwwebsite.com", _"c:\downloads\website.html"
End Sub

据我所知，您不能直接从模块内进行函数调用。

Answer 2

存在一些语法错误。

• 模块语句不是 VBScript。
• 下划线可能会导致意想不到的结果。请参阅 http://technet.microsoft.com/en-us/library/ee198844。 aspx（在页面上搜索单词下划线）
• 调用 Sub 时不能使用括号（例如 xmlhttp.open 是sub，不返回任何内容）。调用子例程有两种主要选择。 sub_proc param1, param2 或 Call sub_proc(param1, param2)
• 赋值运算符“=”对于对象来说是不够的。你应该
  使用设置声明。它将对象引用分配给
  变量。

响应可能会以 utf-8 编码形式返回。但 FSO 与 utf-8 并不一致。另一种选择是将响应写入 unicode（将 True 作为第三个参数传递给 创建文本文件)
但输出大小将大于应有的大小。因此我更愿意使用 < strong>Stream 对象。
我修改了你的代码。请考虑。

'Requeired Constants
Const adSaveCreateNotExist = 1 'only creates if not exists
Const adSaveCreateOverWrite = 2 'overwrites or creates if not exists
Const adTypeBinary = 1

Sub get_html(ByVal up_http, ByVal down_http)
    Dim xmlhttp, varBody
    Set xmlhttp = CreateObject("msxml2.xmlhttp.3.0")
        xmlhttp.open "GET", up_http, False
        xmlhttp.send
        varBody = xmlhttp.responseBody
    Set xmlhttp = Nothing
    Dim str
    Set str = CreateObject("Adodb.Stream")
        str.Type = adTypeBinary
        str.Open
        str.Write varBody
        str.SaveToFile down_http, adSaveCreateOverWrite
        str.Close
    Set str = Nothing
End Sub

get_html "http://stackoverflow.com", "c:\downloads\website.html"