模仿 XSLT 1.0 中的位置（节点集）？

Question

XSLT 2.0 的优点是可以将节点集参数作为position() 函数的一部分进行传递。不幸的是，这在 XSLT 1.0 中不可用。有没有办法模仿这种行为？

例如，给定此 XML:

<wishlists>
  <wishlist name="Games">
    <product name="Crash Bandicoot"/>
    <product name="Super Mario Brothers"/>
    <product name="Sonic the Hedgehog"/>
  </wishlist>
  <wishlist name="Movies">
    <product name="Back to the Future"/>
  </wishlist>
</wishlists>

和此 XSLT 2.0:

<xsl:value-of select="position(/wishlists/wishlist/product)"/>

在处理最终的“回到未来”节点时，将返回值“4”。

不幸的是，我似乎能够使用 XSLT 1.0 获得的最接近值如下：

<xsl:template match="product">
  <xsl:value-of select="position()"/>
</xsl:template>

但是，我会在同一个“回到未来”节点中获得值“1”，而不是我在“回到未来”节点中获得的值“4”。真的想要。

Answer 1

您可以使用前轴。

此 XSLT 1.0 样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="product">
    <product position="{count(preceding::product) + 1}">
      <xsl:apply-templates select="@*"/>
    </product>    
  </xsl:template>

</xsl:stylesheet>

应用于您的 XML 输入会生成：

<wishlists>
   <wishlist name="Games">
      <product position="1" name="Crash Bandicoot"/>
      <product position="2" name="Super Mario Brothers"/>
      <product position="3" name="Sonic the Hedgehog"/>
   </wishlist>
   <wishlist name="Movies">
      <product position="4" name="Back to the Future"/>
   </wishlist>
</wishlists>

Answer 2

XSLT 2.0 的优点是可以将节点集参数作为
位置（）函数。

这种说法是错误的。 position() 函数没有参数——无论是在 XPath 1.0 中还是在 XSLT 2.0 使用的 XPath 2.0 中。

您想要的是：

count(preceding::product) +1

或者，也可以使用xsl:number指令。

以下是这两种方法的演示：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:variable name="vLastProd" select=
  "//product[@name='Back to the Future']"/>

 <xsl:template match="/">
     <xsl:value-of select="count($vLastProd/preceding::product) +1"/>
=========
<xsl:text/>
   <xsl:apply-templates select="$vLastProd"/>
 </xsl:template>

 <xsl:template match="product">
   <xsl:number level="any" count="product"/>    
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<wishlists>
    <wishlist name="Games">
        <product name="Crash Bandicoot"/>
        <product name="Super Mario Brothers"/>
        <product name="Sonic the Hedgehog"/>
    </wishlist>
    <wishlist name="Movies">
        <product name="Back to the Future"/>
    </wishlist>
</wishlists>

使用这两种方法都可以获得所需的正确结果 -- 并且输出：

4
=========
4

注意：如果不直接输出，则需要将xsl:number的结果捕获到变量体内。