此示例代码中数组引用的范围重要吗

Question

#!/usr/bin/perl

    A();
    B();

    sub A {
        my @array = qw(value_1 value_2);
        $array_ref = \@array;
    }

    sub B {
        foreach my $i ( @{$array_ref} ) {
            print "Array Value: $i \n";
        }
    }

由于数组是使用“my”关键字声明的，数组引用是否会丢失？ 任何人都可以向我介绍一下这一点吗？

Answer 1

不，变量的作用域会过期，但内存地址不会过期。数据将保留。

这不是你可以简单尝试一下的吗？ =）我只是复制/粘贴你的代码并尝试了一下，效果很好。

不过，为了正确封装，您实际上应该返回数组引用：

B(A());
# Or
my $aref = A();
B($aref);

sub A {
        my @array = qw(value_1 value_2);
        return \@array;
}

sub B {
    my $array_ref = shift;
    foreach my $i ( @$array_ref ) {
        print "Array Value: $i \n";
    }
}

Answer 2

我绝对推荐

use strict;

在 Perl 脚本中使用（把它放在最开始）。在这种情况下，它会抱怨 $array_ref 未声明为全局的。这可能是造成混乱的主要根源：您使用 $array_ref 而不以任何方式声明它，因此它被视为全局变量。

数组内容本身被保留，因为它被这个变量引用，所以引用计数保持大于 0（perl 在内部使用引用计数来跟踪何时删除变量）。

当然，建议使用 TLP 帖子（没有全局变量）中所示的方法。

Answer 3

实际上，有一个很好的理由在此使用 my示例。
实际上，您希望每次通过子例程都重新创建变量，否则您将更改之前获得的值。

use strict;
use warnings;
use 5.10.1;

my @array;
sub A{
  push @array, scalar @array; # add the length of @array to the end
  return \@array;
}

my @list;

for( 'A'..'D' ){
  my $current = A();
  push @list, $current;
  say join ' ', @$current;
}

say '';

say join ' ', @$_ for @list;

0
0 1
0 1 2
0 1 2 3

0 1 2 3
0 1 2 3
0 1 2 3
0 1 2 3

请注意 @array 的每个副本都是相同的。

---

这就是为什么每次调用子例程时都需要一个新副本的原因。

use strict;
use warnings;
use 5.10.1;

sub A{
  state $iter = 0;
  my @array;
  push @array, 0..$iter++;
  return \@array;
}

my @list;

for( 'A'..'D' ){
  my $current = A();
  push @list, $current;
  say join ' ', @$current;
}

say '';

say join ' ', @$_ for @list;

0
0 1
0 1 2
0 1 2 3

0
0 1
0 1 2
0 1 2 3