如何在XSLT中动态创建节点？

Question

我在 XSLT 转换方面遇到了问题。我输入了如下 XML：

<root>
    <photoname>image</photoname>
    <photocount>3</photocount>
</root>

我需要将其转换为以下 XML：

<root>
    <response>
        <images>
            <image>
                <small>image_1_120.jpg</small>              
            </image>
        </images>
        <images>
            <image>
                <small>image_2_120.jpg</small>              
            </image>
        </images>
        <images>
            <image>
                <small>image_3_120.jpg</small>              
            </image>
        </images>
    </response> 
</root>

它可能与 XSLT（或 XSLT 中的 C# 函数）有关吗？

Answer 1

这是一个非递归解决方案（你需要有足够的节点:)），也称为Piez 方法：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vCount" select="/*/photocount"/>

 <xsl:template match="/*">
     <root>
      <response>
        <xsl:for-each select=
          "(document('')//node())[not(position() > $vCount)]">
                <images>
                  <image>
                      <small>image_1_120.jpg</small>
                  </image>
          </images>
        </xsl:for-each>
      </response>
     </root>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<root>
    <photoname>image</photoname>
    <photocount>3</photocount>
</root>

想要的正确结果是制作：

<root>
   <response>
      <images>
         <image>
            <small>image_1_120.jpg</small>
         </image>
      </images>
      <images>
         <image>
            <small>image_1_120.jpg</small>
         </image>
      </images>
      <images>
         <image>
            <small>image_1_120.jpg</small>
         </image>
      </images>
   </response>
</root>

Answer 2

您可以在 XSLT 中实现此目的，使用 recursize 模板基于 photocount 元素进行迭代

尝试以下 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="root">
      <root>
         <response>
            <xsl:call-template name="photo">
               <xsl:with-param name="name" select="photoname"/>
               <xsl:with-param name="count" select="photocount"/>
            </xsl:call-template>
         </response>
      </root>
   </xsl:template>

   <xsl:template name="photo">
      <xsl:param name="name"/>
      <xsl:param name="count"/>
      <xsl:param name="current" select="1" />
      <images>
         <image>
            <small>
               <xsl:value-of select="concat($name, '_', $current, '_120.jpg')"/>
            </small>
         </image>
      </images>
      <xsl:if test="not($current >= $count)">
         <xsl:call-template name="photo">
            <xsl:with-param name="name" select="$name"/>
            <xsl:with-param name="count" select="$count"/>
            <xsl:with-param name="current" select="$current + 1"/>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>
</xsl:stylesheet>

当应用于示例 XML 时，将输出以下内容：

<root>
   <response>
      <images>
         <image>
            <small>image_1_120.jpg</small>
         </image>
      </images>
      <images>
         <image>
            <small>image_2_120.jpg</small>
         </image>
      </images>
      <images>
         <image>
            <small>image_3_120.jpg</small>
         </image>
      </images>
   </response>
</root>

请注意，我不知道 <生成了strong>_120后缀，因此我必须将其硬编码到XSLT中。

Answer 3

像这样的东西：

<xsl:template match="photocount">
  <xsl:call-template name="for.loop"> 
    <xsl:with-param name="i">1</xsl:with-param> 
    <xsl:with-param name="count" select="." /> 
  </xsl:call-template>  
</xsl:template>

<xsl:template name="for.loop">
  <xsl:param name="i" /> 
  <xsl:param name="count" /> 
  <xsl:if test="$i <= $count">
    <images>
      <image>
        <small>image_<xsl:value-of select="$i"/>_120.jpg</small>              
      </image>
    </images>
  </xsl:if> 

  <xsl:if test="$i <= $count"> 
    <xsl:call-template name="for.loop"> 
      <xsl:with-param name="i"> 
        <xsl:value-of select="$i + 1"/> 
      </xsl:with-param> 
      <xsl:with-param name="count"> 
        <xsl:value-of select="$count"/> 
      </xsl:with-param> 
    </xsl:call-template> 
  </xsl:if> 

</xsl:template> 

Answer 4

解决这个问题可能有很多方法。这是其中之一：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:xs="http://www.w3.org/2001/XMLSchema">

    <xsl:output indent="yes" />

    <xsl:template match="root">
        <xsl:element name="root">
           <xsl:element name="response">

                <xsl:call-template name="output">
                    <xsl:with-param name="name" select="photoname" />
                    <xsl:with-param name="value" select="photocount" />
                </xsl:call-template>

            </xsl:element>

        </xsl:element>
    </xsl:template>

    <xsl:template name="output">
        <xsl:param name="name" />
        <xsl:param name="value" as="xs:integer" />

        <xsl:if test="$value > 1">
            <xsl:call-template name="output">
                <xsl:with-param name="name" select="$name" />
                <xsl:with-param name="value" select="$value - 1" />
            </xsl:call-template>
        </xsl:if>

        <xsl:element name="images">
           <xsl:element name="image">       
               <xsl:element name="small">
                   <xsl:value-of select="concat($name, '_', $value, '_120.jpg')" />
               </xsl:element>
            </xsl:element>
        </xsl:element>

    </xsl:template>
</xsl:stylesheet>

这是我的输出（在 Altova XMLSpy 下）：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <response>
        <images>
            <image>
                <small>image_1_120.jpg</small>
            </image>
        </images>
        <images>
            <image>
                <small>image_2_120.jpg</small>
            </image>
        </images>
        <images>
            <image>
                <small>image_3_120.jpg</small>
            </image>
        </images>
    </response>
</root>