杀死挂起的子进程

Question

我的 Perl 脚本运行一个外部程序（它采用单个命令行参数）并处理其输出。最初，我是这样做的：

my @result = `prog arg`;

然而，事实证明该程序有缺陷，并且在极少数情况下会意外地挂起。如果程序在一段时间后没有退出，我该如何杀死它？该脚本必须在 Windows 和 Linux 中都能工作，据我所知，警报和分叉在 Windows 中不能很好地工作（或根本不能工作）。

我找到了一个名为 IPC::Run 的模块，但我无法从其文档中弄清楚如何正确使用它。 :-( 我尝试了这个：

use strict;
use warnings;
use IPC::Run qw(run timeout);
my $in;
my $out;
my $err;
my @result;
my @cmd = qw(prog arg);
run \@cmd, \$in, \$out, \$err, timeout (10) or die "@cmd: $?";
push @result, $_ while (<$out>);
close $out;
print @result;

作为测试，我创建了一个程序，该程序仅休眠 60 秒，将字符串打印到 stdout 并退出。当我尝试使用上述代码运行它时，它会挂起60 秒（而不是超时中指定的 10 秒）并中止并出现奇怪的错误：

IPC::Run: timeout on timer #1 at C:/Bin/Unix/Perl/site/lib/IPC/Run.pm line 2956

然后我发现了另一个模块，Proc::Reliable 从描述来看，它似乎正是我想要的。只不过它不起作用！我尝试了这个：

use strict;
use warnings;
use Proc::Reliable;

my $proc = Proc::Reliable->new ();
$proc->maxtime (10);
my $out = $proc->run ("prog arg");
print "$out\n";

到目前为止，它确实中止了子进程，但后来我修改了外部程序并使其仅休眠了 5 秒。应该在之前完成上面代码中指定的 10 秒超时及其 stdout 输出应该被捕获到变量 $out 中，但上面的脚本没有输出任何内容！ 任何想法如何正确地做到这一点？

（修复有缺陷的外部程序不是一个选项。）提前致谢。

Answer 1

尝试穷人的警报

my $pid;
if ($^O eq 'MSWin32') {
    $pid = system 1, "prog arg";    # Win32 only, run proc in background
} else {
    $pid = fork();
    if (defined($pid) && $pid == 0) {
        exec("proc arg");
    }
}

my $poor_mans_alarm = "sleep 1,kill(0,$pid)||exit for 1..$TIMEOUT;kill -9,$pid";
system($^X, "-e", $poor_mans_alarm);

穷人的警报在单独的进程中运行。每秒，它都会检查标识符为 $pid 的进程是否仍然存在。如果进程不存在，则警报进程退出。如果进程在 $time 秒后仍然存在，它会向进程发送一个终止信号（我使用 9 使其不可捕获，使用 -9 取出整个子进程树，您的需求可能会有所不同。kill 9,。 .. 也是可移植的）。

编辑：如何捕获穷人警报过程的输出？
不使用反引号——那么您将无法获取进程 ID，并且如果进程超时并被终止，您可能会丢失中间输出。替代方案是

1) 将输出发送到文件，在进程完成时读取文件

$pid = system 1, "proc arg > some_file";
... start poor man's alarm, wait for program to finish ...
open my $fh, '<', 'some_file';
my @process_output = <$fh>;
...

2) 使用 Perl 的 open 启动进程

$pid = open my $proc, '-|', 'proc arg';
if (fork() == 0) {
    # run poor man's alarm in a background process
    exec($^X, '-e', "sleep 1,kill 0,$pid||exit ...");
}
my @process_output = ();
while (<$proc>) {
   push @process_output, $_;
}

while 循环将在进程完成时结束自然或不自然地结束。

Answer 2

这是我能做的最好的了。任何有关如何避免在 Windows 上使用临时文件的想法将不胜感激。

#!/usr/bin/perl

use strict;
use warnings;
use File::Temp;
use Win32::Process qw(STILL_ACTIVE NORMAL_PRIORITY_CLASS);

my $pid;
my $timeout = 10;
my $prog = "prog arg";
my @output;

if ($^O eq "MSWin32")
{
    my $exitcode;
    my $fh = File::Temp->new ();
    my $output_file = $fh->filename;
    close ($fh);
    open (OLDOUT, ">&STDOUT");
    open (STDOUT, ">$output_file" ) || die ("Unable to redirect STDOUT to $output_file.\n");
    Win32::Process::Create ($pid, $^X, $prog, 1, NORMAL_PRIORITY_CLASS, '.') or die Win32::FormatMessage (Win32::GetLastError ());
    for (1 .. $timeout)
    {
        $pid->GetExitCode ($exitcode);
        last if ($exitcode != STILL_ACTIVE);
        sleep 1;
    }
    $pid->GetExitCode ($exitcode);
    $pid->Kill (0) or die "Cannot kill '$pid'" if ($exitcode == STILL_ACTIVE);
    close (STDOUT);
    open (STDOUT, ">&OLDOUT");
    close (OLDOUT);
    open (FILE, "<$output_file");
    push @output, $_ while (<FILE>);
    close (FILE);
}
else
{
    $pid = open my $proc, "-|", $prog;
    exec ($^X, "-e", "sleep 1, kill (0, $pid) || exit for 1..$timeout; kill -9, $pid") unless (fork ());
    push @output, $_ while (<$proc>);
    close ($proc);
}
print "Output:\n";
print @output;

Answer 3

您可能想使用警报系统调用，如 perldoc -f Alarm。