如何使用 AppleScript 的“本地化字符串” Automator 工作流程内部

Question

我在 Mac OS X 10.7 (Lion) 下创建了一个 Automator 工作流服务（不是 Automator 应用程序！），其核心是 AppleScript 操作。该操作需要在多个点通知用户其操作（包括可能的中止），并且我希望将消息本地化为用户的语言。

遵循 Apple 的 字符串本地化指南，我在工作流程包中创建了语言环境资源文件夹（即/Contents/Resources/.lproj/ 文件夹）并将 Localized.strings 文件放置在包含 UTF-16 编码字符串映射的内部。我使用 AppleScript 构造的本地化字符串来调用它们。

当打包到 AppleScript 应用程序包中（经过测试和确认）时，效果很好，但是当在 Automator 生成的服务中使用完全相同的脚本和结构时，本地化会失败 – 我得到的只是原始令牌（请注意 本地化菜单名称 ServicesMenu.strings 拾取得很好 - 资源文件夹结构本身似乎不是问题）。

我的猜测是，问题在于，在 Automator 工作流程中，与应用程序包相反，本地化字符串 的上下文是 Automator（或 Automator Runner，因为它可能是），而不是真正的包，并且因此本地化查找失败。我尝试向服务添加一个捆绑包标识符 (CFBundleIdentifier)，并通过 Automator 自己的 带有标识符 构造的捆绑包中的本地化字符串来引用该标识符，但这似乎仅限于使用 Automator 注册的操作包。

此问题是否有解决方法，允许我在独立的 AppleScript 服务中使用 AppleScript 的本机本地化机制？

Answer 1

本地化字符串命令在 Automator 服务中似乎没有正确的上下文，但您可以使用在通常位置具有资源的任何捆绑包。如果您知道捆绑包在哪里（您的服务工作流程、包含的应用程序等），您可以在命令中指定该路径，例如

get localized string of "testing" in bundle file "path:to:your:bundle"

编辑：以下是对我有用的示例：

我创建了一个新的服务工作流程，它接收任何应用程序中的文本，包含 Run AppleScript 操作：

property myPath : (path to library folder from user domain as text) & "Services:localize test.workflow"

on run {input, parameters}

    try
        display alert getLocalizedString("TESTING") & return & getLocalizedString("NO_ERROR") message "Input Text:    " & quoted form of (input as text)
    on error errmess number errnum
        display alert "Error" & errnum message errmess
    end try

    return input
end run

on getLocalizedString(theString)
    get localized string of theString in bundle file myPath
end getLocalizedString

我将工作流程命名为“localize test”，并将其保存在默认的 ~/Library/Services 文件夹中（这是路径位于myPath 属性）。接下来，将 Localized.strings 文件（使用 BBEdit 创建的 UTF-16）放置在 /Contents/Resources/English.lproj 文件夹中的服务包中，其中包含以下内容：

/* Automator localization test */
"NO_ERROR" = "There seems to have been no error.";
"TESTING" = "Hmmm, works OK for me...";

在我的桌面上使用 AppleScript 脚本包进行的额外测试，添加了相同的资源也运行正常，所以看起来只要您使用有效的包目录结构的路径，任何事情都可以。