Actionscript Getter/setter 类 & OOP 中的范围

Question

背景： 我最近在 AS3 中完成了一个 tic-tac-toe 游戏，使用了一些我多年前用 C 编写的简单的基于函数的代码。 现在，我正在寻求使用 OOP 技术和最佳实践以“正确的方式”做到这一点。 现在所有东西都被分成整齐的小包，看起来很漂亮，我旅程的最后一部分是让所有的小家伙互相交流。

我的困境： 我想将保存游戏状态的代码从我的 main 移动到 com.okaygraphics.model.GameState 中它自己的类。 问题是几乎所有其他包都会获取和设置这些游戏状态属性。 我试图找出封装这些东西的最简单方法，同时仍然允许我的其他类访问它。

我现在的位置：

package com.okaygraphics.model{

    public class GameState {

        private var _player1State:uint=0x00000000;
        private var _player2State:uint=0x00000000;
        private var _activePlayer:int=0;


        public function get p1GameState():uint {
            return _player1State;
        }
        public function set p1GameState(value:uint):void {
            _player1State = value;
        }

        public function get p2GameState():uint {
            return _player2State;
        }
        public function set p2gameState(value:uint):void {
            _player2State = value;
        }

        public function get activePlayer():int {
            return _activePlayer
        }
        public function set activePlayer(value:int):void {
            _activePlayer = value;
        }
    }
}

问题：

1）我需要构造函数吗？我的意思是，我的程序永远不会有多个 GameState。如果我应该将 getter/setter 调用为实例方法，那么如何让每个其他类从各自的包中引用相同的实例？

2）我还需要 getter 和 setter 吗？也许这个类只能有 3 个公共属性？如果是这样，我将如何实现其他课程的适当范围？

3）我应该使用 static 关键字将所有内容分配给类本身吗？如果是这样，我将如何实现和使用这些静态方法？

4）这是一个错误吗？我完全把自己逼到了角落吗？

这似乎是一项非常常见的任务，但我仍然不完全理解。简短的解释、一些链接或我需要的技术的名称将不胜感激。

提前致谢， -最大限度

Answer 1

您可以通过几种不同的方式来解决这个问题。

您可以将 GameState 设为 Singleton。这将确保 GameState 的任何实例都是同一个实例。操作方法如下：

private static var _gameState:GameState;
private static var _allowInstantiation:Boolean;

public function GameState()
{
    if (!_allowInstantiation)
    {
        throw new Error("GameState is a Singleton. Use GameState.getInstance() instead of new GameState().");
    }
    else
    {
        _allowInstantiation = false;
    }
}

public static function getInstance():GameState
{
    if (!_gameState)
    {
        _allowInstantiation = true;
        _gameState = new GameState();
    }

    return _gameState;
}

然后，任何时候您想要获取 GameState 时，都可以使用以下语法：

var _gameState:GameState = GameState.getInstance();

通过使用 Singleton，您仍然可以使用已经创建的 getter 和 setter，但是 Singleton 将确保访问 GameState 的每个类都将访问同一个实例。

或者，如果您不想使用单例，您可以将这些私有变量改为公共静态变量：

public static var player1State:uint=0x00000000;
public static var player2State:uint=0x00000000;
public static var activePlayer:int=0;

您将不再需要 getter/setter，并且您可以从其他类中设置它们，如下所示：

GameState.player1State = 0xFF0000;
GameState.player2State = 0xFF0000;
GameState.activePlayer = 1;

无论哪种方式，您设置模型时，请记住考虑控制器和视图如何与其进行通信。请记住，模型和视图的分离是 MVC 模式的主要目标之一。

Answer 2

1）你可以做的是创建单例类。这是一个只暗示过一次的课程。快速谷歌一下（在 stackoverflow 中搜索 AS3 Singleton），您应该会找到一些很好的单例类示例。对于单例，您只需要包含 GameState 类，并且您将访问唯一的一个。

2）稍后将 getter 和 setter 放在那里只会利大于弊。

3）无法真正回答。

4）不。似乎是要走的路。

Answer 3

我强烈建议您查看 MVC设计模式并在您的游戏中使用它。 （游戏状态是模型的一部分。）

现在，至于如何从所有其他类（这是正确的词而不是包）访问游戏状态，您可以使用 单例模式。