Haskell 中的行多态性：使用“转换”编写 Forth DSL 时遇到问题

Question

我受到最近的 Haskell 博客活动¹的启发，尝试在 Haskell 中编写类似 Forth 的 DSL。我采取的方法既简单又令人困惑：

{-# LANGUAGE TypeOperators, RankNTypes, ImpredicativeTypes #-}

-- a :~> b represents a "stack transformation"
--          from stack type "a" to stack type "b"
-- a :> b represents a "stack" where the top element is of type "b"
--          and the "rest" of the stack has type "a"
type s :~> s' = forall r. s -> (s' -> r) -> r
data a :> b = a :> b deriving Show
infixl 4 :>

对于做简单的事情，这非常有效：

start :: (() -> r) -> r
start f = f ()

end :: (() :> a) -> a
end (() :> a) = a

stack x f = f x
runF s = s end
_1 = liftS0 1
neg = liftS1 negate
add = liftS2 (+)

-- aka "push"
liftS0 :: a -> (s :~> (s :> a))
liftS0 a s = stack $ s :> a

liftS1 :: (a -> b) -> ((s :> a) :~> (s :> b))
liftS1 f (s :> a) = stack $ s :> f a

liftS2 :: (a -> b -> c) -> ((s :> a :> b) :~> (s :> c))
liftS2 f (s :> a :> b) = stack $ s :> f a b

简单的函数可以轻松地转换为相应的堆栈转换。到目前为止，一些尝试产生了令人愉快的结果：

ghci> runF $ start _1 _1 neg add
0

当我尝试用高阶函数扩展它时，麻烦就来了。

-- this requires ImpredicativeTypes...not really sure what that means
-- also this implementation seems way too simple to be correct
-- though it does typecheck. I arrived at this after pouring over types
-- and finally eta-reducing the (s' -> r) function argument out of the equation
-- call (a :> f) h = f a h
call :: (s :> (s :~> s')) :~> s'
call (a :> f) = f a

call应该转换形式的堆栈>(s :> (s :~> s')) 为 s 形式，本质上是通过将变换（保存在堆栈的顶部）“应用”到它的“休息”。我想它应该像这样工作：

ghci> runF $ start _1 (liftS0 neg) call
-1

但实际上，它给了我一个巨大类型不匹配错误。我做错了什么？ “堆栈变换”表示是否足以处理高阶函数，或者我是否需要调整它？

¹NB 与这些人的做法不同，我希望它是 runF $ start (push 1) (push 2）添加，这个想法是也许稍后我可以使用一些类型类魔法来使push对某些文字隐式。

• https://github.com/leonidas /codeblog/blob/master/2012/2012-02-17-concatenative-haskell.md
• https://gist.github.com/1847747

Answer 1

问题是您的类型同义词是多态类型

type s :~> s' = forall r. s -> (s' -> r) -> r

使用多态类型作为 -> 之外的类型构造函数的参数称为“必然性”。例如，以下内容将是谓语用法

Maybe (forall a. a -> a)

由于各种原因，具有谓语性的类型推断很困难，这就是 GHC 抱怨的原因。 （“谓语”这个名字来自逻辑和柯里-霍华德同构。）

在您的情况下，解决方案只是使用带有构造函数的代数数据类型：

data s :~> s' = StackArr { runStackArr :: forall r. s -> (s' -> r) -> r}

基本上，显式构造函数 StackArr 为类型检查器提供了足够的提示。

或者，您可以尝试 ImpredicativeTypes 语言扩展。

Answer 2

您的 :~> 类型不是您真正想要的类型（因此是 ImpredicativeTypes）。如果您只是从 call 中删除类型注释，那么您的最后一个示例将按预期工作。让它工作的另一种方法是使用不那么花哨但更合适的类型和额外的参数：

type Tran s s' r = s -> (s' -> r) -> r

call :: Tran (s :> (Tran s s' r)) s' r
call (a :> f) = f a

但是如果你追求的是一个很好的 DSL 语法并且你可以容忍 OverlappingInstances 那么你甚至可以得到摆脱 liftSx 功能：

{-# LANGUAGE TypeOperators, MultiParamTypeClasses, TypeFamilies,
             FlexibleInstances, FlexibleContexts,
             UndecidableInstances, IncoherentInstances  #-}

data a :> b = a :> b deriving Show
infixl 4 :>


class Stackable s o r where
    eval :: s -> o -> r


data End = End

instance (r1 ~ s) => Stackable s End r1 where
    eval s End = s


instance (Stackable (s :> a) o r0, r ~ (o -> r0)) => Stackable s a r where
    eval s a = eval (s :> a)

instance (a ~ b, Stackable s c r0, r ~ r0) => Stackable (s :> a) (b -> c) r where
    eval (s :> a) f = eval s (f a)

-- Wrap in Box a function which should be just placed on stack without immediate application
data Box a = Box a

instance (Stackable (s :> a) o r0, r ~ (o -> r0)) => Stackable s (Box a) r where
    eval s (Box a) = eval (s :> a)


runS :: (Stackable () a r) => a -> r
runS a = eval () a

-- tests
t1 = runS 1 negate End
t2 = runS 2 1 negate (+) End

t3 = runS 1 (Box negate) ($) End
t4 = runS [1..5] 0 (Box (+)) foldr End
t5 = runS not True (flip ($)) End

t6 = runS 1 (+) 2 (flip ($)) End