如何删除文件的最后5行

Question

我有几个使用 perl 将文本打印到文件的命令。在这些 print 命令中，我有一个 if 语句，如果该语句为真，则应删除我当前正在写入的文件的最后 5 行。要删除的行数始终为 5。

if ($exists == 0) {
  print(OUTPUT ???) # this should remove the last 5 lines
}

Answer 1

您可以使用 Tie::File：

use Tie::File;
tie my @array, 'Tie::File', filename or die $!;

if ($exists == 0) {
    $#array -= 5;
}

打印时可以使用相同的数组，但使用 push 代替：

push @array, "line of text";

Answer 2

$ tac file | perl -ne 'print unless 1 .. 5' | tac > file.tailchopped

Answer 3

我能想到的唯一明显的方法：

1. 锁定文件，扫描 向后查找位置并使用
   截断。
2. 不要直接打印到文件，而是通过缓冲区
   至少有 5 行长，然后修剪缓冲区。
3. 打印一个标记，表示“忽略最后五行”。
   在使用缓冲区读取所有文件之前先对其进行处理，如 #2 中所示。

所有这些都非常繁琐，但这恐怕就是平面文件的本质。

华泰

Answer 4

作为替代方案，打印除最后 5 行之外的整个文件：

open($fh, "<", $filename) or die "can't open $filename for reading: $!";
open($fh_new, ">", "$filename.new") or die "can't open $filename.new: $!";
my $index = 0; # So we can loop over the buffer
my @buffer;
my $counter = 0;
while (<$fh>) {
    if ($counter++ >= 5) {
        print $fh_new $buffer[$index];
    }
    $buffer[$index++] = $_;
    $index = 0 if 5 == $index;
}
close $fh;
close $fh_new;
use File::Copy;
move("$filename.new", $filename) or die "Can not copy $filename.new to $filename: $!";

Answer 5

File::ReadBackwards+truncate 对于大文件来说是最快的，对于短文件来说可能与其他任何东西一样快。

use File::ReadBackwards qw( );

my $bfh = File::ReadBackwards->new($qfn)
   or die("Can't read \"$qfn\": $!\n");

$bfh->readline() or last for 1..5;

my $fh = $bfh->get_handle();
truncate($qfn, tell($fh))
   or die $!;

Tie::File 最慢，并且使用大量内存。避免该解决方案。

Answer 6

你可以尝试这样的事情：

open FILE, "<", 'filename';
if ($exists == 0){
 @lines = <FILE>;
 $newLastLine = $#lines - 5;   
 @print = @lines[0 .. $newLastLine];
 print "@print";
}

或者甚至缩短：

open FILE, "<", 'filename';
@lines = <FILE>;
if ($exists == 0){
 print "@lines[0 .. $#lines-5]";
}