如何也使用 Perl 哈希中键的替代字符作为键？

Question

我的代码：

use strict;  
use warnings;

my $seq = "ATGGT[TGA]G[TA]GC";  
print "The sequences is $seq\n";  
my %regex = (  
   AG => "R",  
   TC => "Y",  
   GT => "K",  
   AC => "M",  
   GC => "S",  
   AT => "M",  
   CGT => "B",  
   TGA => "D",  
   ACT => "H",  
   ACG => "V",  
   ACGT => "N"  
);  

$seq =~ s/\[(\w+)\]/$regex{$1}/g;  
print "$seq\n";  

我的理想输出是：ATGGTDGMGC 但在上面的场景中，由于我的哈希密钥是 AT 而不是 TA，因此它无法运行。解决这个问题的一种方法是添加另一个键值： TA => “M”。但我无法对所有键值对执行此操作，因为可能性太多。

那么有没有更好的方法来解决这个问题呢？

谢谢..

Answer 1

我猜你的意思是括号中内容的顺序并不重要，因此 AT 相当于 TA，而 TAG 相当于 < code>TGA 等

[请注意，另一个 Eric 做出了不同的猜测。你不是很清楚自己想要什么。 ]

你可以对字母进行排序。

sub key { join '', sort split //, $_[0] }

my @subs = (
   AG => "R",
   TC => "Y",
   GT => "K",
   AC => "M",
   GC => "S",
   AT => "M",
   CGT => "B",
   TGA => "D",
   ACT => "H",
   ACG => "V",
   ACGT => "N",
);  

my %subs;
while (@subs) {
    my $key = shift(@subs);
    my $val = shift(@subs);
    $subs{ key($key) } = $val;
}

# Die on unrecognized
$seq =~ s/\[(\w+)\]/ $subs{ key($1) } or die $1 /ge;

或者

# Do nothing on unrecognized
$seq =~ s/\[(\w+)\]/ $subs{ key($1) } || $1 /ge;

Answer 2

Perl 无法知道键 AT 与 TA 的含义相同，除非您以某种方式告诉它。如果所有序列都可以颠倒，那么您可以执行以下操作：

for (keys %regex) {
   $regex{reverse $_} = $regex{$_}
}

您可能还应该检查以确保没有覆盖任何现有密钥。

或者，您可以修改正则表达式：

$seq =~ s/\[(\w+)\]/$regex{$1} or $regex{reverse $1}
        or die "pattern $1 not found"/ge;  

同样，这两个示例都假设您的所有密钥都可以反转。如果没有，那么您将必须手动输入冲销，或制定某种冲销选择标准。