使用 CUDA 缩放矩阵的行

Question

在 GPU 上的一些计算中，我需要缩放矩阵中的行，以便给定行中的所有元素总和为 1。

| a1,1 a1,2 ... a1,N |    | alpha1*a1,1 alpha1*a1,2 ... alpha1*a1,N |
| a2,1 a2,2 ... a2,N | => | alpha2*a2,1 alpha2*a2,2 ... alpha2*a2,N |
| .            .   |    | .                                .    |
| aN,1 aN,2 ... aN,N |    | alphaN*aN,1 alphaN*aN,2 ... alphaN*aN,N |

其中

alphai =  1.0/(ai,1 + ai,2 + ... + ai,N)

我需要 alpha 向量和缩放后的矩阵我希望尽可能少地调用 blas 来完成此操作。该代码将在 nvidia CUDA 硬件上运行。有谁知道有什么聪明的方法可以做到这一点？

Answer 1

Cublas 5.0 引入了一个类似 blas 的例程，称为 cublas(Type)dgmm，它是矩阵与对角矩阵（由向量表示）的乘法。

有一个左侧选项（将缩放行）或一个右侧选项将缩放列。

详细信息请参阅 CUBLAS 5.0 文档。

因此，在您的问题中，您需要创建一个包含 GPU 上所有 alpha 的向量，并使用 cublasdgmm 和 left 选项。

Answer 2

如果您将 BLAS gemv 与单位向量一起使用，结果将是您需要的缩放因子 (1/alpha) 倒数的向量。这是最简单的部分。

逐行应用因子有点困难，因为标准 BLAS 没有类似 Hadamard 乘积运算符的功能可供使用。另外，因为您提到了 BLAS，我推测您正在为矩阵使用列主序存储，这对于行操作来说并不那么简单。 非常慢的方法是在每一行上以间距进行 BLAS scal，但这需要每行一次 BLAS 调用和由于对合并和 L1 缓存一致性的影响，倾斜的内存访问会降低性能。

我的建议是使用您自己的内核进行第二次操作。它不必那么复杂，也许只需像这样：

template<typename T>
__global__ void rowscale(T * X, const int M, const int N, const int LDA,
                             const T * ralpha)
{
    for(int row=threadIdx.x; row<M; row+=gridDim.x) {
        const T rscale = 1./ralpha[row]; 
        for(int col=blockIdx.x; col<N; col+=blockDim.x) 
            X[row+col*LDA] *= rscale;
    }
}

只有一堆块按列逐行遍历，并在行进时进行缩放。应该适用于任何大小的列主有序矩阵。内存访问应该合并，但根据您对性能的担忧程度，您可以尝试多种优化。它至少给出了该做什么的总体思路。

Answer 3

我想用一个考虑使用 CUDA Thrust 的 thrust::transform 和 cuBLAS 的 cublasdgmm 的示例来更新上面的答案>。我跳过缩放因子 alpha 的计算，因为这已经在

使用 CUDA 减少矩阵行

和

使用 CUDA 减少矩阵列

下面是一个完整的示例：

#include <thrust/device_vector.h>
#include <thrust/reduce.h>
#include <thrust/random.h>
#include <thrust/sort.h>
#include <thrust/unique.h>
#include <thrust/equal.h>

#include <cublas_v2.h>

#include "Utilities.cuh"
#include "TimingGPU.cuh"

/**************************************************************/
/* CONVERT LINEAR INDEX TO ROW INDEX - NEEDED FOR APPROACH #1 */
/**************************************************************/
template <typename T>
struct linear_index_to_row_index : public thrust::unary_function<T,T> {

    T Ncols; // --- Number of columns

    __host__ __device__ linear_index_to_row_index(T Ncols) : Ncols(Ncols) {}

    __host__ __device__ T operator()(T i) { return i / Ncols; }
};

/***********************/
/* RECIPROCAL OPERATOR */
/***********************/
struct Inv: public thrust::unary_function<float, float>
{
    __host__ __device__ float operator()(float x)
    {
        return 1.0f / x;
    }
};

/********/
/* MAIN */
/********/
int main()
{
    /**************************/
    /* SETTING UP THE PROBLEM */
    /**************************/

    const int Nrows = 10;           // --- Number of rows
    const int Ncols =  3;           // --- Number of columns  

    // --- Random uniform integer distribution between 0 and 100
    thrust::default_random_engine rng;
    thrust::uniform_int_distribution<int> dist1(0, 100);

    // --- Random uniform integer distribution between 1 and 4
    thrust::uniform_int_distribution<int> dist2(1, 4);

    // --- Matrix allocation and initialization
    thrust::device_vector<float> d_matrix(Nrows * Ncols);
    for (size_t i = 0; i < d_matrix.size(); i++) d_matrix[i] = (float)dist1(rng);

    // --- Normalization vector allocation and initialization
    thrust::device_vector<float> d_normalization(Nrows);
    for (size_t i = 0; i < d_normalization.size(); i++) d_normalization[i] = (float)dist2(rng);

    printf("\n\nOriginal matrix\n");
    for(int i = 0; i < Nrows; i++) {
        std::cout << "[ ";
        for(int j = 0; j < Ncols; j++)
            std::cout << d_matrix[i * Ncols + j] << " ";
        std::cout << "]\n";
    }

    printf("\n\nNormlization vector\n");
    for(int i = 0; i < Nrows; i++) std::cout << d_normalization[i] << "\n";

    TimingGPU timerGPU;

    /*********************************/
    /* ROW NORMALIZATION WITH THRUST */
    /*********************************/

    thrust::device_vector<float> d_matrix2(d_matrix);

    timerGPU.StartCounter();
    thrust::transform(d_matrix2.begin(), d_matrix2.end(),
                      thrust::make_permutation_iterator(
                                d_normalization.begin(),
                                thrust::make_transform_iterator(thrust::make_counting_iterator(0), linear_index_to_row_index<int>(Ncols))),
                      d_matrix2.begin(),
                      thrust::divides<float>());
    std::cout << "Timing - Thrust = " << timerGPU.GetCounter() << "\n";

    printf("\n\nNormalized matrix - Thrust case\n");
    for(int i = 0; i < Nrows; i++) {
        std::cout << "[ ";
        for(int j = 0; j < Ncols; j++)
            std::cout << d_matrix2[i * Ncols + j] << " ";
        std::cout << "]\n";
    }

    /*********************************/
    /* ROW NORMALIZATION WITH CUBLAS */
    /*********************************/
    d_matrix2 = d_matrix;

    cublasHandle_t handle;
    cublasSafeCall(cublasCreate(&handle));

    timerGPU.StartCounter();
    thrust::transform(d_normalization.begin(), d_normalization.end(), d_normalization.begin(), Inv());
    cublasSafeCall(cublasSdgmm(handle, CUBLAS_SIDE_RIGHT, Ncols, Nrows, thrust::raw_pointer_cast(&d_matrix2[0]), Ncols, 
                   thrust::raw_pointer_cast(&d_normalization[0]), 1, thrust::raw_pointer_cast(&d_matrix2[0]), Ncols));
    std::cout << "Timing - cuBLAS = " << timerGPU.GetCounter() << "\n";

    printf("\n\nNormalized matrix - cuBLAS case\n");
    for(int i = 0; i < Nrows; i++) {
        std::cout << "[ ";
        for(int j = 0; j < Ncols; j++)
            std::cout << d_matrix2[i * Ncols + j] << " ";
        std::cout << "]\n";
    }

    return 0;
}

Utilities.cu 和 Utilities.cuh 文件被维护 此处并省略此处。 TimingGPU.cu 和 TimingGPU.cuh 维护于此处< /a> 和 也被省略。

我已在 Kepler K20c 上测试了上述代码，结果如下：

                 Thrust      cuBLAS
2500 x 1250      0.20ms      0.25ms
5000 x 2500      0.77ms      0.83ms

在 cuBLAS 计时中，我排除了 cublasCreate 时间。即便如此，CUDA Thrust 版本似乎更方便。