F#：有没有办法扩展 monad 关键字列表？

Question

在 F# monad 中，如果您说 let!，编译器会将其转换为您在 monad 构建器上定义的 Bind 成员。

现在我看到有查询单子，如 所示在 MSDN 上，您可以在其中说：

query {
    for student in db.Student do
    select student
    count
}

select 和 count 例如，将被翻译为 QueryBuilder 成员<一href="https://msdn.microsoft.com/visualfsharpdocs/conceptual/querybuilder.select%5B%27t%2C%27q%2C%27result%5D-method-%5Bfsharp%5D" rel="noreferrer">Linq。 QueryBuilder.Select 和 Linq.QueryBuilder .计数。

我的问题是，关键字到成员的映射是硬连线到 F# 编译器中的，还是可扩展的？例如，我可以这样说：

FooMonadBuilder() {
    bar
}

并以某种方式告诉 F# 编译器 bar 映射到 FooMonadBuilder.Bar() 方法吗？

Answer 1

在 F# 2.0（即 Visual Studio 2010）中，无法扩展关键字列表（Ramon 的扩展除外）。但是，F# 3.0 (Visual Sutdio 11) 中的查询机制是可扩展的，您可以定义自己的关键字，类似于 select 和 count。

下面是一个基本示例，它使用 reverse 关键字定义了诸如 seq 构建器之类的内容：

type SeqBuilder() =
    // Standard definition for 'for' and 'yield' in sequences
    member x.For (source : seq<'T>, body : 'T -> seq<'R>) =
      seq { for v in source do yield! body v }
    member x.Yield item =
      seq { yield item }

    // Define an operation 'select' that performs projection
    [<CustomOperation("select")>]
    member x.Select (source : seq<'T>, [<ProjectionParameter>] f: 'T -> 'R) : seq<'R> =
        Seq.map f source

    // Defines an operation 'reverse' that reverses the sequence    
    [<CustomOperation("reverse", MaintainsVariableSpace = true)>]
    member x.Expand (source : seq<'T>) =
        List.ofSeq source |> List.rev

let mseq = SeqBuilder()

其工作原理的详细信息尚未记录，但有 CustomOperation 属性表示该操作应被视为特殊语法（您可以设置各种属性来指定其行为方式 - MaintainsVariableSpace 意味着它不会更改序列内的值）。 Projectionparameter 属性指定关键字后面的表达式应隐式转换为函数。

现在，mseq 构建器支持 select 和 reverse：

let q = mseq { for i in 1 .. 10 do
               select (i + 100)
               reverse }

Answer 2

简短的回答：不。

我已经扩展了编译器来支持这一点，欢迎您阅读我的博客文章 http://ramon.org.il/wp/2011/04/take-computation-expressions-one-step-further/