Racket 中的条件模式匹配

Question

由于指南中的所有示例都带有列表，因此我发现很难了解如何在 Racket 中使用模式匹配来编写像 OCaml 那样的条件匹配，例如：

read ~var_a var_b s = match s.[0] with
    | _ when var_b >= var_a + 4 ->
        (* Do something *)
    | "a" when is_negative var_b -> 
        (* Do something else *)
    ...

我如何在 Racket 中编写类似的内容？

谢谢。

Answer 1

racket/match 库包含可以通过以下方式使用任意谓词的模式匹配： ? 模式。与 和 一起，您应该能够让 Racket 的匹配器正常工作。虽然我的 OCaml 能力有点弱，但我认为上面代码的以下翻译与其含义相符：

(define (my-read #:var-a var-a var-b s)
  (match (string-ref s 0)
    [(and _
          (? (lambda (_)
               (>= var-b (+ var-a 4)))))
     "do something"]
    [(and '#\a
          (? (lambda (_)
               (< var-b 0))))
     "do something else"]))

;; Exercising the first case:     
(my-read #:var-a 50
         60 "blah")

;; Exercising the second case:
(my-read #:var-a 50
         -40 "alphabet")

? 匹配器内嵌了隐式 and ，因此代码可以更简洁地表达为：

(define (my-read #:var-a var-a var-b s) 
  (match (string-ref s 0)
    [(? (lambda (_)
          (>= var-b (+ var-a 4))))
     "do something"]
    [(? (lambda (_)
          (< var-b 0))
        #\a)
     "do something else"]))

在这两种情况下，其中的 lambda 不观察匹配的内容，因此我只是将它们命名为 _ 来表示不关心。但是您可以想象更复杂的模式，其中谓词可以深入关心确切匹配的内容。

Eli 建议在这里使用通用的 cond，因为代码中没有任何重要的模式匹配。我同意。代码如下所示：

(define (my-read #:var-a var-a var-b s) 
  (cond
    [(>= var-b (+ var-a 4))
     "do something"]
    [(and (char=? (string-ref s 0) #\a)
          (< var-b 0))
     "do something else"]))

Answer 2

模式匹配可以很容易地转化为一系列测试，没有一种语言不能做到这一点。

OCaml（可能还有 Haskell）模式匹配的优点在于，编译器在可能的情况下将代码转换为最佳测试序列（即程序永远不会测试两次相同的条件，至少当您避免 当守卫时）。