使用 Pig Latin 选择不同的计数

Question

我需要关于这个猪脚本的帮助。我只得到一条记录。我选择 2 列并对另一列进行计数（不同），同时还使用 where like 子句来查找特定描述 (desc)。

这是我正在尝试编写的带有 Pig 的 sql。

 /*
    For example in sql:
    select domain, count(distinct(segment)) as segment_cnt
    from table
    where desc='ABC123'
    group by domain
    order by segment_count desc;
    */

    A = LOAD 'myoutputfile' USING PigStorage('\u0005')
            AS (
                domain:chararray,
                segment:chararray,
                desc:chararray
                );
B = filter A by (desc=='ABC123');
C = foreach B generate domain, segment;
D = DISTINCT C;
E = group D all;
F = foreach E generate group, COUNT(D) as segment_cnt;
G = order F by segment_cnt DESC;

Answer 1

您可以对每个域进行 GROUP，然后使用 嵌套 FOREACH 语法：

D = group C by domain;
E = foreach D { 
    unique_segments = DISTINCT C.segment;
    generate group, COUNT(unique_segments) as segment_cnt;
};

Answer 2

您可以更好地将其定义为宏：

DEFINE DISTINCT_COUNT(A, c) RETURNS dist {
  temp = FOREACH $A GENERATE $c;                                                                                                                                                      
  dist = DISTINCT temp;                                                                                                                                                               
  groupAll = GROUP dist ALL;                                                                                                                                                          
  $dist = FOREACH groupAll GENERATE COUNT(dist);                                                                                                                                      
}

用法：

X = LOAD 'data' AS (x: int);

Y = DISTINCT_COUNT(X, x);

如果您需要在 FOREACH 中使用它，最简单的方法如下：

...GENERATE COUNT(Distinct(x))...

在 Pig 12 上测试。

Answer 3

如果你不想依赖任何团体，你可以使用这个：

G = FOREACH (GROUP A ALL){
unique = DISTINCT A.field;
GENERATE COUNT(unique) AS ct;
};

这只会给你一个数字。