SectionProperties.AddSection 无法正常工作 - bug？

Question

我刚刚遇到了SectionProperties.AddSection 的错误行为。假设我已经创建了四个部分：

1. Default
2. Overview
3. Details
4. Conclusions

现在我调用代码：

Presentation.SectionProperties.AddSection(3, "Overview details");

根据文档： SectionProperties.AddSection 方法 (PowerPoint) 概述详细信息 部分应在详细信息部分之前创建。

没有得到

1. Default
2. Overview
3. Overview Details
4. Details
5. Conclusions

但我最终

1. Default
2. Overview details
3. Overview
4. Details
5. Conclusions

答案：这是一个常见问题吗？我做了一些测试，似乎只有在开头或结尾插入新部分时，插入新部分才能正常工作。

谢谢， 帕韦乌

Answer 1

在 MS Answers 上也看到了您的帖子，在这之间，有更多的时间来研究这个。这确实有问题，但有一个解决方法。当某些部分没有幻灯片时会出现此问题；因此，我们将向任何没有幻灯片的部分添加幻灯片，根据需要添加该部分，然后删除刚刚添加的“虚拟”幻灯片。

Sub TestAddSection()
    Dim x As Long
    Dim oSl As Slide

    ' Add a dummy slide to each empty section and tag it
    For x = 1 To ActivePresentation.SectionProperties.Count
        Debug.Print ActivePresentation.SectionProperties.Name(x)
        If ActivePresentation.SectionProperties.SlidesCount(x) = 0 Then
          ' activepresentation.SectionProperties.
          Set oSl = ActivePresentation.Slides.AddSlide(1, ActivePresentation.Designs(1).SlideMaster.CustomLayouts(1))
          oSl.Tags.Add "DUMMY", "YES"
          oSl.MoveToSectionStart (x)
        End If
    Next

    ' add new section
    ActivePresentation.SectionProperties.AddSection 3, "NEW GUY"

    ' And delete the dummy slides
    With ActivePresentation
        For x = .Slides.Count To 1 Step -1
            If .Slides(x).Tags("DUMMY") = "YES" Then
                .Slides(x).Delete
            End If
        Next
    End With
End Sub

我将幻灯片添加到索引 1 处，然后将它们移动到需要它们的部分的开头。也许有一种方法可以将它们直接添加到该部分，但我找不到。