我们可以在 Jess 中计算具有相同值的事实吗？

Question

使用 Jess 作为规则引擎，我们可以断言某个证人在某个地点看到了一个人，并且与时间相关：

(deffacts witnesses
    (witness Batman Gotham 18)
    (witness Hulk NYC 19)
    (witness Batman Gotham 2)
    (witness Superman Chicago 22)
    (witness Batman Gotham 10)
)

通过规则，我想知道是否有多个证人在同一地点看到了同一个人，不考虑时间。

在 Jess 文档中，我们得到了这个示例，用于计算工资为 10 万及以上的员工：

(defrule count-highly-paid-employees
    ?c <- (accumulate (bind ?count 0)                        ;; initializer
    (bind ?count (+ ?count 1))                    ;; action
    ?count                                        ;; result
    (employee (salary ?s&:(> ?s 100000)))) ;; CE
    =>
    (printout t ?c " employees make more than $100000/year." crlf))

因此，我的代码基于前面的示例：

(defrule count-witnesses
    (is-lost ?plost)
    (witness ?pseen ?place ?time)
    ?c <- (accumulate (bind ?count 0)
    (bind ?count (+ ?count 1))
    ?count
    (test ())  ; conditional element of accumulate
    (test (= ?plost ?pseen))
    (test (>= ?count 3))
    =>
    (assert (place-seen ?place))
)

使用上面提供的“(deffacts)”指令和规则，引擎应该断言这一事实​​，

(place-seen Gotham)

因为我们有蝙蝠侠在哥谭市见过三遍。

我不知道如何使用“累积”的条件元素（CE）部分。我可以使用“测试”来保留同一个人和同一地点的事实吗？

知道如何实现这一目标吗？

谢谢你！

---

注意：“累积”的合成是

(accumulate <initializer> <action> <result> <conditional element>)

Answer 1

我将省略有关 ?plos 的内容，因为您没有准确解释那是什么；如果需要，您可以自己将其添加回来。

（几乎）做你想要的事情的基本规则如下。您没有得到的 CE 部分只是我们想要积累的一个模式；在这里，它会将事实与在同一地点见证的同一个人与第一个人匹配的事实相匹配：

(defrule count-witnesses
  ;; Given that some person ?person was seen in place ?place
  (witness ?person ?place ?)  
  ;; Count all the sightings of that person in that place  
  ?c <- (accumulate (bind ?count 0)
                    (bind ?count (+ ?count 1))
                    ?count
                    (witness ?person ?place ?))
  ;; Don't fire unless the count is at least 3
  (test (>= ?c 3))
  =>
  (assert (place-seen ?person ?place))
)

现在，此规则的唯一问题是它会针对您的 deffacts 触发三次，每一个蝙蝠侠/哥谭事实都一次。我们可以通过更改第一个模式来仅匹配某个人在给定地点的最早出现来阻止这种情况：

(defrule count-witnesses
  ;; Given that some person ?person was seen in place ?place, and there is no other 
  ;; sighting of the same person at the same place at an earlier time
  (witness ?person ?place ?t1)    
  (not (witness ?person ?place ?t2&:(< ?t2 ?t1)))
  ;; Count all the sightings of that person in that place  
  ?c <- (accumulate (bind ?count 0)
                    (bind ?count (+ ?count 1))
                    ?count
                    (witness ?person ?place ?))
  ;; Don't fire unless the count is at least 3
  (test (>= ?c 3))
  =>
  (assert (place-seen ?person ?place))
)