我可以在 cfscript 中调用自定义标签吗？

Question

例如，如果我有一个像 这样的自定义标签，我的假设将类似于 AppSwitch(action="Check")，但是我不确定 CF 是否可以将其解析为自定义标签。

我能想到的另一个解决方案是编写一个包装函数并调用我的自定义标签，但这感觉多余。

看来我过于简单化了一个更复杂的问题，所以 任何见解将不胜感激（即使是为什么不/不应该支持）。

Answer 1

更新2：

这是一个更糟糕的方式（或者是一个糟糕的断言者？）。警告：下面未记录的功能（但仍然很酷）：

假设自定义标记返回如下值：

<cfif thisTag.executionMode eq "start">
    <cfparam name="attributes.name" default="Dude" />
    <cfparam name="attributes.result" type="variablename" default="result" />
    <cfset caller[attributes.result] = "Hello, " & attributes.name & "!!" />
</cfif>

因此标记的结果属性需要一个将设置到调用者中的变量名称。现在使用下面的方法我们可以通过 cfscript 访问该结果。

<cfscript>

test = createObject("java", "coldfusion.tagext.lang.ModuleTag");
test.setPageContext( getPageContext() );
test.setTemplatePath(expandPath('echo.cfm'));
test.setAttributeCollection({name="Todd Sharp", result="testResult"});
test.doStartTag();
test.doEndTag();
test.releaseTag();

writeDump(testResult);

</cfscript>

更新：

以下解决方案可能会导致不良副作用。如果您的自定义标记返回一个值，您将无法访问它，因为该标记是从组件调用的，返回变量将被放入组件的变量范围中，而不是调用模板。当然，如果您要返回一个值，您可能应该使用 CFC（正如我上面评论的那样），因此使用风险自负。

这种方法怎么样（从 Jake 的修改而来）：

CustomTagProxy.cfc:

<cfcomponent>

    <cffunction name="onMissingMethod" output="false">
        <cfargument name="missingMethodName" type="string"/>
        <cfargument name="missingMethodArguments" type="struct"/>

            <cfset var returnVal = "">
            <cfsavecontent variable="returnVal"><cfmodule template="#arguments.missingMethodName#.cfm" attributecollection="#arguments.missingMethodArguments#" /></cfsavecontent>
            <cfreturn returnVal>
    </cffunction>

</cfcomponent>

echo.cfm:

<cfif thisTag.executionMode eq "start">
    <cfparam name="attributes.name" default="Dude" />
    <cfoutput>Hello, #attributes.name#!!</cfoutput>
</cfif>

time.cfm:

<cfif thisTag.executionMode eq "start">
    <cfoutput>It is now #now()#.</cfoutput>
</cfif>

index.cfm:

<cfscript>
proxy = new CustomTagProxy();
echoTest = proxy.echo(name="Todd");
timeTest = proxy.time();

writeOutput(echoTest);
writeOutput("<br />");
writeOutput(timeTest); 
</cfscript>

Answer 2

假设您使用的是 Adob​​e CF，不幸的是答案是否定的。您必须编写一个基于 CFML 的包装函数。例如：

<cffunction name="myCustomTag">
  <cfset var returnVal = "">
  <cfsavecontent variable="returnVal"><cf_myCustomTag attributeCollection=arguments></cfsavecontent>
  <cfreturn returnVal>
</cffunction>

<cfscript>
 myCustomTag(a="b");
</cfscript>

现在，如果您使用 Railo，则可以使用与 < 等效的 cfscript ;cfmodule> 标签：

<cfscript>
    module name="myCustomTag";
</cfscript>

Answer 3

2021 年更新：

ColdFusion 的最新版本增强了 cfscript 支持，将允许您调用类似于函数的自定义标记。

<cf_custtag att1="value1" att2="value2">

相当于

<cfscript>    
    cf_custtag(att1="value1", att2="value2");
</cfscript>

我还没有找到嵌套自定义标签或获取 generatedContent 的本机解决方案，所以我做了一个解决方法。

我使用名为“ generatedContentOverride”的自定义属性将内容传递到自定义标记。

在自定义标记代码中，我查找该属性并使用它来代替 thisTag. generatedContent。