Nmap：使用 Batch 和 Blat 提取不需要的端口以发送邮件

Question

上下文

我使用 FINDSTR /C:"portid=" "scanports.xml" 从文件中提取这些行：

<port protocol="tcp" portid="21"><state state="open" reason="syn-ack" reason_ttl="124"/><service name="ftp" method="table" conf="3"/></port>
<port protocol="tcp" portid="22"><state state="open" reason="syn-ack" reason_ttl="124"/><service name="ssh" method="table" conf="3"/></port>
<port protocol="tcp" portid="80"><state state="open" reason="syn-ack" reason_ttl="124"/><service name="http" method="table" conf="3"/></port>
<port protocol="tcp" portid="443"><state state="open" reason="syn-ack" reason_ttl="124"/><service name="https" method="table" conf="3"/></port>
<port protocol="tcp" portid="3389"><state state="open" reason="syn-ack" reason_ttl="124"/><service name="ms-term-serv" method="table" conf="3"/></port>

问题

• 如何提取 21, 22、80、443 和 3389 来自这一行？
• 对于 [0-9] 中的随机数有同样的问题，除了 21、22、80、443 和 3389？

我想通过电子邮件发送所有通常不打开的打开端口。

Answer 1

您可以使用第二个 FINDSTR 来过滤掉“常开”端口。我展示的解决方案使用外部文件来列出要排除的端口（常开端口）。或者，可以在命令行上将列表指定为多个 /C 选项。

ignore.txt（根据需要编辑）

portid="21"
portid="22"
portid="80"
portid="443"
portid="3389"

findstr /c:"portid=" test.txt | findstr /r /v /g:"ignore.txt"

FINDSTR 存在一个错误，如果存在多个不同长度的文字搜索字符串，它可能无法找到匹配项。这就是我选择使用 /R 正则表达式选项的原因。

如果 XML 文件的格式一致，则可以使用 FOR /F 并将 DELIMS 设置为引号字符来提取第四个标记。使用引号作为分隔符指定 FOR /F 选项的语法很奇怪：通常您会执行类似 "tokens=4 delims=," 的操作。但是要包含引号作为分隔符，您必须进行一系列转义：tokens^=4^ delims^=^"。

将它们放在一起，您

@echo off
for /f tokens^=4^ delims^=^" %%P in (
  'findstr /c:"portid=" test.txt ^| findstr /r /v /g:"ignore.txt"'
) do (
  echo unusual open port = %%P
)
exit /b

将得到 XML 的格式（属性顺序）可能会有所不同，那么解决方案会更复杂，首先使用外部 FOR /F 将整行读入变量，然后使用 SET * 搜索并替换 op 来查找字符串中的 portid 位置，然后使用第二个 FOR。 /F 解析 隔离出实际端口

setlocal enableDelayedExpansion
for /f "delims=" %%L in (
  'findstr /c:"portid=" test.txt ^| findstr /r /v /g:"ignore.txt"'
) do (
  set "ln=%%L"
  for /f delims^=^=^" %%A in ("!ln:*portid=!") do set port=%%A
  echo unusual open port = !port!
)

后，我建议您使用 Blat for Windows 发送您的电子邮件。

Answer 2

您可以使用 FOR/F 来解析行。

FINDSTR /C:"portid=" "scanports.xml" > tmpFile.tmp

FOR /F "tokens=3 delims=>=" %%1 in (tmpFile.tmp) DO (
  echo %%~1
)

Answer 3

这有点作弊，但是您的批处理文件可以调用 VBScript 脚本：

c:\windows\system32\cscript.exe //nologo scanports.vbs

其中 scanports.vbs 是以下脚本：

Option Explicit
Dim xml, port
Set xml = CreateObject("Microsoft.XMLDOM")
xml.load "scanports.xml"
For Each port in xml.documentElement.selectNodes("//port")
  WScript.Echo port.getAttribute("portid")
Next

Answer 4

我用 jeb 的回答 和 此链接。

代码：

@ECHO Off
SETLOCAL ENABLEDELAYEDEXPANSION

REM Blat options:
SET blat="C:\Program Files (x86)\blat276\full\blat.exe"
SET server=127.0.0.1
SET port=25
SET [email protected]
SET [email protected]

FOR %%i IN (1,1,9) DO (  
  "C:\Program Files (x86)\Nmap\nmap.exe" server%%i.com -oX scanports%%i.xml

  FINDSTR /C:"portid=" scanports%%i.xml >> scanports%%itemp.txt

  FOR /F "tokens=*" %%a IN (scanports%%itemp.txt) DO (
    SET x=%%a
    SET x=!x:"=/!
    FOR /f "tokens=4,12 delims=/" %%a IN ("!x!") DO (
      IF NOT %%a==21 IF NOT %%a==22 IF NOT %%a==80 IF NOT %%a==443 IF NOT %%a==3389 (
        %blat% -server %server% -port %port% -f %from% -to %to% -html -s "Port ouvert sur server%%i" -body "Port %%a : %%b"
      )
    )
  )
  
  DEL scanports%%i.xml
  DEL scanports%%itemp.txt
)