使普通的一元函数与等效的一元转换器一起工作

Question

我正在尝试解决平衡括号问题。我不想进行连续的 IO，而宁愿对 getLine 进行一次调用并解析结果字符串。因此，解决问题的函数将处理两种不同的状态：输入字符串的未消耗部分和括号堆栈。

我想设置一些用于操作堆栈的函数：

type Stack = String

pop :: Stack -> (Char,Stack)
pop (x:xs) = (x,xs)

push :: Char -> Stack -> ((),Stack)
push a xs = ((),a:xs)

如果我在状态 monad 中操作，那一切都很好，但是我在 StateT monad 中操作，

balanced :: StateT Stack (State String) Bool

我知道我被告知不要在堆栈中包含重复的 monad。我这样做是因为我喜欢它如何简化推送和弹出定义。

两个问题：

1. 无论我做什么，我都找不到将push和pop应用于 StateT 中包含的堆栈。
2. 我不知道如何从主函数中调用它

这是其余的代码

next :: String -> (Maybe Char,String)
next ""     = (Nothing,[])
next (x:xs) = (Just x,xs)

balanced = do
            c <- lift (state next)
            case c of
              Nothing -> return True
              Just c  -> if elem c open 
                         then (push c) >> balanced
                         else if elem c close 
                              then pop >>= \x ->
                                if eq x c
                                then balanced
                                else return False
                              else balanced
          where open  = "<{(["
                close = "])}>"
                eq '(' ')' = True
                eq '{' '}' = True
                eq '<' '>' = True
                eq '[' ']' = True
                eq  _   _  = False

Answer 1

您的问题是您的 push 和 pop 只是普通的非单子函数，您试图在单子 do 块中使用它们。您正确使用了 next，因为您使用 state 函数调用它，但正如您可能注意到的那样，state 仅适用于普通的 State monad 而不是 StateT。

我们可以像这样实现 state 的 monad 转换器版本：

stateT :: Monad m => (s -> (a, s)) -> StateT s m a
stateT f = do
    (x, s') <- gets f
    put s'
    return x

然后在 balanced 函数中使用 push 和 pop.

balanced :: StateT Stack (State String) Bool
balanced = do
            c <- lift (state next)
            case c of
              Nothing -> return True
              Just c  -> if elem c open
                         then (stateT $ push c) >> balanced
                         else if elem c close
                              then stateT pop >>= \x ->
                                if eq x c
                                    then balanced
                                    else return False
                              else balanced
          where open  = "<{(["
                close = "])}>"
                eq '(' ')' = True
                eq '{' '}' = True
                eq '<' '>' = True
                eq '[' ']' = True
                eq  _   _  = False

该函数的调用方式如下：

evalState (evalStateT balanced []) s

其中 s 是初始字符串，[] 是初始堆栈。