perl 将单个变量封装在双引号中

Question

在 Perl 中，是否有任何理由将单个变量封装在双引号中（无连接）？

我经常在我正在开发的程序的源代码中发现这一点（由不再在这里工作的人在 10 年前编写）：

my $sql_host = "something";
my $sql_user = "somethingelse";

# a few lines down
my $db = sub_for_sql_conection("$sql_host", "$sql_user", "$sql_pass", "$sql_db");

据我所知，没有理由这样做。当我使用旧脚本时，我通常会删除引号，以便我的编辑器将它们着色为变量而不是字符串。

我认为他们在某处看到了这一点并复制了这种风格，但不明白为什么会这样。我错过了什么吗？

谢谢。

Answer 1

这一切所做的就是显式地对变量进行字符串化。在 99.9% 的情况下，这是某种新手错误。

这种调用方式可能会产生一些副作用：

my $foo = "1234";
sub bar { $_[0] =~ s/2/two/ }
print "Foo is $foo\n";
bar( "$foo" );
print "Foo is $foo\n";
bar( $foo );
print "Foo is $foo\n";

这里，字符串化创建了一个副本并将其传递给子例程，从而绕过了 Perl 的按引用传递语义。通常认为修改调用变量是不礼貌的行为，所以你可能没问题。

您还可以在此处对对象或其他值进行字符串化。例如，undef 字符串化为空字符串。对象可以指定在字符串化时运行的任意代码。可以有具有不同数值和字符串值的双值标量。这是一种指定您想要字符串形式的方法。

还有一件可能正在发生的令人毛骨悚然的事情。如果您正在使用查看函数标量参数上设置的标志的 XS 代码，则对标量进行字符串化是对 perl 说的一种直接方式，“为我创建一个漂亮的干净的新字符串值”，仅使用字符串标志和没有数字标志。

我确信 99.9% 规则还有其他奇怪的例外。这是一些。在删除引号之前，请花一点时间检查一下是否有像这样的奇怪的废话。如果您确实发现了合法的用法，请添加一条评论，将这些引用标识为可行的拼凑，并给出它们存在的理由。

Answer 2

在这种情况下，双引号是不必要的。此外，使用它们的效率很低，因为这会导致原始字符串被复制。

但是，有时您可能想使用此样式来“字符串化”对象。例如， URI 对象支持字符串化：

my $uri = URI->new("http://www.perl.com");
my $str = "$uri";

Answer 3

我不知道为什么，但这是 Perl 新手常用的模式。这通常是一种浪费（因为它在您发布的代码片段中），但我可以想到两种用途。

---

它的作用是创建一个与原始字符串具有相同值的新字符串，这在极少数情况下可能很有用。

在下面的示例中，显式复制是为了保护 $x 不被子程序修改，因为子程序修改了它的参数。

$ perl -E'
   sub f { $_[0] =~ tr/a/A/; say $_[0]; }
   my $x = "abc";
   f($x);
   say $x;
'
Abc
Abc

$ perl -E'
   sub f { $_[0] =~ tr/a/A/; say $_[0]; }
   my $x = "abc";
   f("$x");
   say $x;
'
Abc
abc

---

通过创建字符串的副本，它将对象字符串化。当处理根据其参数是否为引用来改变其行为的代码时，这可能很有用。

在以下示例中，显式字符串化已完成，因为 require 处理 @INC 中的引用的方式与字符串不同。

$ perl -MPath::Class=file -E'
   BEGIN { $lib = file($0)->dir; }
   use lib $lib;
   use DBI;
   say "ok";
'
Can't locate object method "INC" via package "Path::Class::Dir" at -e line 4.
BEGIN failed--compilation aborted at -e line 4.

$ perl -MPath::Class=file -E'
   BEGIN { $lib = file($0)->dir; }
   use lib "$lib";
   use DBI;
   say "ok";
'
ok

Answer 4

在你的情况下，引号完全没有用。我们甚至可以说这是错误的，因为这不是惯用的，正如其他人所写的那样。

然而，有时可能需要引用变量：这会显式触发变量值的字符串化。如果某些值是对偶变量或者它们是具有 重载ed 字符串化。

这是一个双变量的示例：

use 5.010;
use strict;
use Scalar::Util 'dualvar';

my $x = dualvar 1, "2";
say 0+$x;
say 0+"$x";

输出：

1
2

Answer 5

我的理论一直是，来自其他语言的人有坏习惯。并不是他们在想“我会一直使用双引号”，而是他们只是没有想！

老实说，我曾经陷入过这个陷阱，因为我是从 Java 转到 Perl 的，所以肌肉记忆就在那里，并且一直在发挥作用。

PerlCritic 终于让我戒掉了这个习惯！

它肯定会让你的代码更高效，但是如果你没有考虑是否要对字符串进行插值，你很可能会犯愚蠢的错误，所以我会更进一步说这是危险的。