如何编写 sed 脚本来从文本文件中 grep 信息

Question

我正在尝试做我的作业，仅限于使用 sed 将输入文件过滤为某种输出格式。这是输入文件（名为 stocks）：

Symbol;Name;Volume
================================================

BAC;Bank of America Corporation Com;238,059,612
CSCO;Cisco Systems, Inc.;28,159,455
INTC;Intel Corporation;22,501,784
MSFT;Microsoft Corporation;23,363,118
VZ;Verizon Communications Inc. Com;5,744,385
KO;Coca-Cola Company (The) Common;3,752,569
MMM;3M Company Common Stock;1,660,453

================================================

输出需要是：

BAC, CSCO, INTC, MSFT, VZ, KO, MMM

我确实想出了一个解决方案，但效率不高。这是我的 sed 脚本（名为 try.sed）：

/.*;.*;[0-9].*/ { N
N
N
N
N
N
s/\(.*\);.*;.*\n\(.*\);.*;.*\n\(.*\);.*;.*\n\(.*\);.*;.*\n\(.*\);.*;.*\n\(.*\);.*;.*\n\(.*\);.*;.*/\1, \2, \3, \4, \5, \6, \7/gp
}

我在 shell 上运行的命令是：

$ sed -nf try.sed stocks

我的问题是，是否有更好的方法使用 sed 来获取相同的结果？我写的脚本只能处理 7 行数据。如果数据较长，我需要重新修改我的脚本。我不知道如何才能让它变得更好，所以我在这里寻求帮助！

感谢您的任何建议。

Answer 1

另一种使用 sed 的方法：

sed -ne '/^====/,/^====/ { /;/ { s/;.*$// ; H } }; $ { g ; s/\n// ; s/\n/, /g ; p }' stocks

输出：

BAC, CSCO, INTC, MSFT, VZ, KO, MMM

解释：

-ne               # Process each input line without printing and execute next commands...
/^====/,/^====/   # For all lines between these...
{
  /;/             # If line has a semicolon...
  { 
    s/;.*$//      # Remove characters from first semicolon until end of line.
    H             # Append content to 'hold space'.
  }
};
$                 # In last input line...
{
  g               # Copy content of 'hold space' to 'pattern space' to work with it.
  s/\n//          # Remove first newline character.
  s/\n/, /g       # substitute the rest with output separator, comma in this case.
  p               # Print to output.

Answer 2

编辑：我已经编辑了我的算法，因为我忽略了页眉和页脚（我认为它们只是为了我们的利益）。

sed 根据其设计，访问输入文件的每一行，然后对与某些规范匹配（或不匹配）的行执行表达式。如果您将脚本定制为一定数量的行，那么您肯定做错了什么！我不会为您编写脚本，因为这是家庭作业，但一种方法的总体思路是编写一个执行以下操作的脚本。将顺序视为脚本中事物应有的顺序。

1. 使用 d 跳过前三行，这会删除模式空间并立即移至下一行。
2. 对于不是空行的每一行，执行以下步骤。 （这一切都在一组花括号中。）
   1. 使用 s（替换）命令将第一个分号 (;) 之后的所有内容替换为逗号和空格 (", ")。李>
   2. 将当前模式空间附加到保持缓冲区（查看H）。
   3. 删除模式空间并移至下一行，如步骤 1 所示。
3. 对于脚本中到达此点的每一行（应该是第一个空行），将保留空间的内容检索到模式空间中。 （这将在上面的大括号之后。）将
4. 模式空间中的所有换行符替换为空。
5. 接下来，将模式空间中的最后一个逗号和空格替换为空。
6. 最后，退出程序，这样就不再处理任何行。我的脚本在没有这个的情况下也能工作，但我不能 100% 确定为什么。

话虽这么说，这只是解决问题的一种方法。 sed 通常提供不同复杂程度的不同方法来完成任务。我用这种方法编写的解决方案有 10 行长。

请注意，我不费心抑制打印（使用 -n）或手动打印（使用 p）；默认情况下打印每一行。我的脚本运行如下：

$ sed -f companies.sed companies 
BAC, CSCO, INTC, MSFT, VZ, KO, MMM

Answer 3

此 sed 命令应生成您所需的输出：

sed -rn '/[0-9]+$/{s/^([^;]*).*$/\1/p;}' file.txt

或者在 Mac 上：

sed -En '/[0-9]+$/{s/^([^;]*).*$/\1/p;}' file.txt

Answer 4

这可能对您有用：

sed '1d;/;/{s/;.*//;H};${g;s/.//;s/\n/, /g;q};d' stocks

• 我们不需要标题，所以让我们删除它们。 1d
• 所有数据项均由 ; 分隔，因此让我们重点关注这些行。 /;/
• 上述内容中，删除从第一个 ; 到行尾的所有内容，然后将其塞入保留空间 (HS) {s /;.*//;H}
• 当到达最后一行时，使用 g 命令用 HS 覆盖它，删除第一个换行符（由 H 生成） 命令），用逗号和空格替换所有后续换行符并打印出剩下的内容。 ${g;s/.//;s/\n/, /g;q}
• 删除其他所有内容 d

这是一个终端会话，显示了构建sed命令：

cat <<! >stock # paste the file into a here doc and pass it on to a file
> Symbol;Name;Volume
> ================================================
> 
> BAC;Bank of America Corporation Com;238,059,612
> CSCO;Cisco Systems, Inc.;28,159,455
> INTC;Intel Corporation;22,501,784
> MSFT;Microsoft Corporation;23,363,118
> VZ;Verizon Communications Inc. Com;5,744,385
> KO;Coca-Cola Company (The) Common;3,752,569
> MMM;3M Company Common Stock;1,660,453
> 
> ================================================
> !
sed '1d;/;/!d' stock # delete headings and everything but data lines
BAC;Bank of America Corporation Com;238,059,612
CSCO;Cisco Systems, Inc.;28,159,455
INTC;Intel Corporation;22,501,784
MSFT;Microsoft Corporation;23,363,118
VZ;Verizon Communications Inc. Com;5,744,385
KO;Coca-Cola Company (The) Common;3,752,569
MMM;3M Company Common Stock;1,660,453
sed '1d;/;/{s/;.*//p};d' stock # delete all non essential data
BAC
CSCO
INTC
MSFT
VZ
KO
MMM
sed '1d;/;/{s/;.*//;H};${g;l};d' stock # use the l command to see what's really there!
\nBAC\nCSCO\nINTC\nMSFT\nVZ\nKO\nMMM$
sed '1d;/;/{s/;.*//;H};${g;s/.//;s/\n/, /g;l};d' stock # refine refine
BAC, CSCO, INTC, MSFT, VZ, KO, MMM$
sed '1d;/;/{s/;.*//;H};${g;s/.//;s/\n/, /g;q};d' stock # all done!
BAC, CSCO, INTC, MSFT, VZ, KO, MMM