使用把手迭代 javascript 对象

Question

我正在尝试向 Handlebars 注册助手，以允许迭代 JSON 对象。 这个要点看起来是一个合适的解决方案。我将其转换为以下 CoffeeScript。当我使用任何一个帮助程序时，似乎什么都没有发生（这对于普通 JavaScript 和 CoffeeScript 版本都适用）。有什么想法吗？

$ ->
  Handlebars.registerHelper "key_value", (obj, fn)->
    buffer = ""
    key 
    for key in obj 
      if obj.hasOwnProperty(key)
        buffer += fn({key: key, value: obj[key]})
    buffer

  Handlebars.registerHelper "each_with_key", (obj, fn)->
    context
    buffer = ""
    key 
    keyName = fn.hash.key
    for key in obj 
      if obj.hasOwnProperty(key)
        context = obj[key]
        if keyName
          context[keyName] = key 
          buffer += fn(context)
    buffer

在模板中：

{{#key_value categories}}
I'M ALIVE!!
{{/key_value}}

{{#each_with_key categories key="category_id"}}
I'M ALIVE!!
{{/each_with_key}}

我目前正在 Gemfile 中使用 gem 'handlebars-assets' 将车把添加到 Rails 应用程序中。

Answer 1

您的 JavaScript 到 CoffeeScript 的音译已损坏。您不使用 for ... in 来迭代 CoffeeScript 中的对象，而是使用 for k, v ...：

使用 of 来表示对对象属性的理解，而不是对数组中的值的理解。

这个 CoffeeScript 循环：

for x in y
    ...

变成这个 JavaScript：

for (_i = 0, _len = y.length; _i < _len; _i++) {
  x = a[_i];
  ...
}

所以如果 y 是一个没有 length 属性的对象，那么 _len 将是 undefined 和 JavaScript for(;;) 循环根本不会迭代。

您还应该使用 own 而不是 hasOwnProperty：

如果您只想迭代对象本身定义的键，请添加 hasOwnProperty 检查以避免可能从原型中迭代的属性，请使用 for own对象的键，值。

但这更多是为了方便而不是正确性。

另外，CoffeeScript 循环是表达式，因此您通常会说 array = expr for own k, v in o 或等效形式：

array = for own k, v in o
    expr

if expr 超过一行或太多很长以便于可读理解。

CoffeeScript 中助手的正确且更惯用的版本看起来更像是这样的：

Handlebars.registerHelper "key_value", (obj, fn)->
    (fn(key: key, value: value) for own key, value of obj).join('')

Handlebars.registerHelper "each_with_key", (obj, fn)->
    key_name = fn.hash.key
    buffer   = for own key, value of obj
        value[key_name] = key
        fn(value)
    buffer.join('')

演示： http://jsfiddle.net/ambigously/LWTPv/