flash.utils.IExternalized +远程处理Flex 错误 #2004

Question

有一个客户端-服务器基本应用程序。客户端使用简单的远程处理与服务器端进行通信。服务器端可以由WebORB、BlazeDS 或任何其他产品供电。客户端使用FLEX框架。这就是关于技术堆栈的内容。现在，让我们忘记服务器端，只看一下以下客户端

package com.blog.ri
{
    import mx.collections.ArrayCollection;

    public class MyCollection extends ArrayCollection
    {
        public function MyCollection(source:Array=null)
        {
            super(source);
        }
    }   
}

此外，假设我们有以下类并且它映射到服务器端类：

package com.blog.ri
{
    [Bindable]
    [RemoteClass(alias="com.blog.ri.MyEntity")]
    public dynamic class MyEntity
    {   
        private var _myCollection:MyCollection;

        public function get myCollection():MyCollection
        {
            if(_myCollection == null)
                _myCollection = new MyCollection();

            return _myCollection;
        }

        public function set myCollection(value:MyCollection):void
        {
            _myCollection = value;
        }       
    }
}

此外，服务器端服务向客户端公开 void save( MyEntity候选）方法，我在客户端实现了它，如下所示：

package com.blog.ri
{
    public class MyService
    {       
        private var _remoteObject:RemoteObject;

        public function MyService()
        {
            var channelSet:ChannelSet = new ChannelSet();
            var amfChannel:AMFChannel = new AMFChannel("my-amf", "http://localhost/weborb.aspx");
            channelSet.addChannel(amfChannel);

            _remoteObject  = new RemoteObject("GenericDestination");
            _remoteObject.channelSet = channelSet;
            _remoteObject.source = "com.blog.ri.MyService";
            _remoteObject.getDetailedStatistic.addEventListener("result",onItemSaved);
            _remoteObject.addEventListener("fault", onFault);
        }

        public function save(candidate:MyEntity, responder:IResponder = null ):void
        {
            var asyncToken:AsyncToken = _remoteObject.save(candidate);

            if( responder != null )
                asyncToken.addResponder( responder );
        }

    }
} 

最后，我尝试在主 mxml 文件中保存 MyEntity 类的新实例，如下所示：

protected function creationCompleteHandler():void
            {
                var myService:MyService = new MyService();

                var candidate:MyEntity = new MyEntity();
                candidate.myCollection = new MyCollection();

                myService.save(candidate);
            }

就是这样。当我运行代码时，我收到以下异常：

ArgumentError：错误#2004：参数之一无效。在 flash.net::NetConnection/invokeWithArgsArray() 位于 flash.net::NetConnection/call() 位于 mx.messaging.channels::NetConnectionChannel/internalSend()[E:\dev\hero_private\frameworks\projects\rpc\src\mx\messaging\channels\NetConnectionChannel.as:281] 在 mx.messaging.channels::AMFChannel/internalSend()[E:\dev\hero_private\frameworks\projects\rpc\src\mx\messaging\channels\AMFChannel.as:364] 在 mx.messaging::Channel/send()[E:\dev\hero_private\frameworks\projects\rpc\src\mx\messaging\Channel.as:1002] 在 mx.messaging.channels::PollingChannel/send()[E:\dev\hero_private\frameworks\projects\rpc\src\mx\messaging\channels\PollingChannel.as:394] 在 mx.messaging::ChannelSet/send()[E:\dev\hero_private\frameworks\projects\rpc\src\mx\messaging\ChannelSet.as:1429] 在 mx.messaging::ChannelSet/channelConnectHandler()[E:\dev\hero_private\frameworks\projects\rpc\src\mx\messaging\ChannelSet.as:1084] 在 flash.events::EventDispatcher/dispatchEventFunction() 处 flash.events::EventDispatcher/dispatchEvent() 在 mx.messaging::Channel/connectSuccess()[E:\dev\hero_private\frameworks\projects\rpc\src\mx\messaging\Channel.as:1148] 在 mx.messaging.channels::AMFChannel/resultHandler()[E:\dev\hero_private\frameworks\projects\rpc\src\mx\messaging\channels\AMFChannel.as:576]

如您所见，我扩展了 ArrayCollection 类根据 Adob​​e 文档，ArrayCollection 实现了 IExternalized 接口。我决定本地化问题并创建一个实现 IExternalized 的简单类。然后，我在其他一些 MyChild 类中扩展了此类，并在 MyEntity 类中定义了 MyChild 属性。在这种情况下，我也收到了上面的异常。是我编写代码的方式有问题还是flex中的错误？

感谢您的任何帮助。 这个问题在我的博客中重复了。

Answer 1

你可以尝试：

            registerClassAlias( "mx.collections.ArrayCollection", ArrayCollection);
            registerClassAlias("flex.messaging.io.ArrayCollection", ArrayCollection);

Answer 2

尝试为 MyCollection 添加别名。

我收到了无用的错误#2004，直到我所有实现 IExternalized 的类都有别名。就我而言，这是为了持久化（ViewNavigatorApplicationBase.persistNavigatorState = true），在这种情况下，我必须确保在启动时尽早调用 registerClassAlias，以便在 View.deserializeData() 之前调用。应用程序上的预初始化事件工作正常。

Answer 3

您的某些正在（反）序列化的类可能未链接到 Flex 项目中。尝试将以下内容添加到您的主应用程序/模块文件中：

private var forceReference:Array = [YourClass1, YourClass2];