如果文件中的第一行与模式匹配，则删除它

Question

我想知道是否有一种有效的方法来删除文件中的第一行（如果它与指定模式匹配）。例如，我有一个包含以下形式数据的文件：

Date,Open,High,Low,Close,Volume,Adj.Volume
2012-01-27,42.38,42.95,42.27,42.68,2428000,42.68
2012-01-26,44.27,44.85,42.48,42.66,5785700,42.66
.
.
.

我想删除第一行，仅当它包含文本时（如第一行示例所示），如果它仅包含数字，则保持不变（如其余行所示）。这项任务非常简单，我通过应用以下代码来完成它，该代码将每一行写入 $newFile 只要它不包含 Date 模式：

while( <$origFile> )
    {
        chomp($_);
        print $newFile $_ unless ($_  =~ m/Date/g)
    }

正如我所提到的，这就完成了工作。然而，当已知文本只能出现在第一行时，读取整个文件中的每一行似乎是对资源的极大浪费。

有什么方法可以更有效地完成此任务吗？

注意：我已经在此处找到了一个几乎类似的问题，但由于我希望我的代码也可以在 Linux 和 Windows 上使用，因此使用 sed 在这里对我没有帮助。

提前致谢！

Answer 1

$. 可用于确定是否正在处理文件的第一行。

perl -i.bak -ne'print if $. != 1 || !/^Date/;' file

然而，读取整个文件中的每一行似乎是对资源的极大浪费

除了文件末尾之外，不可能从任何地方删除。要从开头或中间删除，文件中后面的所有内容都需要移动，这意味着它必须既可读取又可写入。

如果第一行不匹配，您只能避免工作（什么都不做）。如果需要删除该行，则必须复制整个文件。

Answer 2

Tie::File 模块非常适合此目的。它非常高效，因为它执行块 IO 而不是一次读取一行，并且使程序编写起来非常简单。

use strict;
use warnings;

use Tie::File;

tie my @data, 'Tie::File', 'mydatafile' or die $!;
shift @data if $data[0] =~ /Date/;
untie @data;

Answer 3

仅在第一行进行测试，然后运行文件的其余部分而不检查：

if (defined( $_ = <$origFile> )) {
    if ( ! m/Date/o ) { print $newFile $_ }

    my $data;

    for (;;) {
        my $readRes = read($origFile, $data, 0x10000);

        if (!defined $readRes) { die "Can't read: $!" }

        if ($readRes == 0) { last }

        print $newFile $data;
    }
}