Delphi XE2：禁用组件上的 vcl 样式

Question

我正在尝试按照有关禁用表单上控件上的颜色的示例进行操作。

TStyleManager.Engine.RegisterStyleHook(ClrMeans.TwwDBComboDLG, TEditStyleHook);

但在注册或取消注册第 3 方控件 (infopower TwwDBComboDlg) 或标准 VCL TEdit 时出现异常。有人对此有任何问题或建议

Answer 1

这里的链接解释了您需要了解的内容。

基本上，您需要放入一个“空钩子”，这是您已经知道的，或者需要放入一个“VCL 颜色”钩子，这是您所缺少的一半。另一半是你的零指针问题。

为了使 TEdit 衍生品（像你的）看起来像 VCL 标准颜色，你需要让它与你的控件一起工作的代码是这样的：

uses
  Winapi.Messages,
  Vcl.Controls,
  Vcl.StdCtrls,
  Vcl.Forms,
  Vcl.Themes,
  Vcl.Styles;

type

TEditStyleHookColor = class(TEditStyleHook)
  private
    procedure UpdateColors;
  protected
    procedure WndProc(var Message: TMessage); override;
    constructor Create(AControl: TWinControl); override;
  end;

implementation


type
 TWinControlH= class(TWinControl);


constructor TEditStyleHookColor.Create(AControl: TWinControl);
begin
  inherited;
  //call the UpdateColors method to use the custom colors
  UpdateColors;
end;

//Here you set the colors of the style hook
procedure TEditStyleHookColor.UpdateColors;
var
  LStyle: TCustomStyleServices;
begin
 if Control.Enabled then
 begin
  Brush.Color := TWinControlH(Control).Color; //use the Control color
  FontColor   := TWinControlH(Control).Font.Color;//use the Control font color
 end
 else
 begin
  //if the control is disabled use the colors of the style
  LStyle := StyleServices;
  Brush.Color := LStyle.GetStyleColor(scEditDisabled);
  FontColor := LStyle.GetStyleFontColor(sfEditBoxTextDisabled);
 end;
end;

//Handle the messages of the control
procedure TEditStyleHookColor.WndProc(var Message: TMessage);
begin
  case Message.Msg of
    CN_CTLCOLORMSGBOX..CN_CTLCOLORSTATIC:
      begin
        //Get the colors
        UpdateColors;
        SetTextColor(Message.WParam, ColorToRGB(FontColor));
        SetBkColor(Message.WParam, ColorToRGB(Brush.Color));
        Message.Result := LRESULT(Brush.Handle);
        Handled := True;
      end;
    CM_ENABLEDCHANGED:
      begin
        //Get the colors
        UpdateColors;
        Handled := False;
      end
  else
    inherited WndProc(Message);
  end;
end;

Procedure ApplyVCLColorsStyleHook(ControlClass :TClass);
begin
    if Assigned(TStyleManager.Engine) then
       TStyleManager.Engine.RegisterStyleHook(ControlClass, TEditStyleHookColor);
end;

initialization
     ApplyVCLColorsStyleHook(TwwDBComboDlg);

NIL 的问题是，如果你没有打开 VCL 主题，那么 Engine 为零，并且您应该检查并从该代码返回，而不调用您正在调用的函数。如果您错过了，您可以在此处打开主题：

有趣的附带内容：获取 VCL 样式实用程序 库。下面是一个使用它来更改内容颜色的示例：

 TCustomStyleExt(TStyleManager.ActiveStyle).SetStyleColor(scEdit, clWindow);
 TCustomStyleExt(TStyleManager.ActiveStyle).SetStyleFontColor(sfEditBoxTextNormal
                   ,clWindowText);

您可以创建样式，并将这些样式应用到特定控件，甚至扩展主题引擎，可能可以使用 VCL Styles Utils 工具来获得所需的结果，但是这并不是一件小事。