从另一个批处理文件运行一个批处理文件

Question

我想从批处理文件 2(C:) 运行批处理文件 1(路径 C:\3rdparty\Test\App) VS2008.sln 位于 C:\3rdparty\Test\App\VS2008

批处理文件 1

REM BatchFile1.bat

set DEVENV_PATH=%VS90COMNTOOLS%..\IDE

REM ---------------------------------------------------------------------

set OUTDIR=.\output\windows\x86
rmdir /S /Q %OUTDIR%
mkdir %OUTDIR%

call "%DEVENV_PATH%\devenv.com" VS2008\VS2008.sln /Rebuild "Release|Win32"
call "%DEVENV_PATH%\devenv.com" VS2008\VS2008.sln /Rebuild "Debug|Win32"

REM ---------------------------------------------------------------------

set OUTDIR=.\output\windows\x64
rmdir /S /Q %OUTDIR%
mkdir %OUTDIR%

call "%DEVENV_PATH%\devenv.com" VS2008\VS2008.sln /Rebuild "Release|x64"
call "%DEVENV_PATH%\devenv.com" VS2008\VS2008.sln /Rebuild "Debug|x64"

REM ---------------------------------------------------------------------


echo "BatchFile1.bat completed."

批处理文件 2

echo "Running Batch File 2"
call C:\3rdparty\Test\App\BatchFile1.bat

此处，当从 Batchfile2 调用批处理文件 1 时，由于路径不同，因此无法执行 VS2008.sln。 我不想更改批处理文件 1。是否可以更改批处理文件 2 来执行批处理文件 1。

Answer 1

尝试将目录更改为 BatchFile1 的目录。

echo "Running Batch File 2" 
cd C:\3rdparty\Test\App
call BatchFile1.bat 

Answer 2

我已在脚本中添加了一个本地变量，该变量设置为 BatchFile1 路径（无论它是什么），因此现在您可以使用相对于 BatchFile1 路径的路径。

REM BatchFile1.bat

set scriptPath=%~dp0
set scriptPath=%scriptPath:~0,-1%

rem now %scriptPath%  contain the script path, and then you can use command like
rem "%scriptPath%\MyCommand.exe" /MyParameter=123_abcd


set DEVENV_PATH=%VS90COMNTOOLS%..\IDE

REM ---------------------------------------------------------------------

set OUTDIR=.\output\windows\x86
rmdir /S /Q %OUTDIR%
mkdir %OUTDIR%

call "%DEVENV_PATH%\devenv.com" "%scriptPath%\VS2008\VS2008.sln" /Rebuild "Release|Win32"
call "%DEVENV_PATH%\devenv.com" "%scriptPath%\VS2008\VS2008.sln" /Rebuild "Debug|Win32"

REM ---------------------------------------------------------------------

set OUTDIR=.\output\windows\x64
rmdir /S /Q %OUTDIR%
mkdir %OUTDIR%

call "%DEVENV_PATH%\devenv.com" "%scriptPath%\VS2008\VS2008.sln" /Rebuild "Release|x64"
call "%DEVENV_PATH%\devenv.com" "%scriptPath%\VS2008\VS2008.sln" /Rebuild "Debug|x64"

REM ---------------------------------------------------------------------


echo "BatchFile1.bat completed."

Answer 3

您可以将

pushd %~dp0

这

popd

代码放在batchfile1.bat中，

会将当前目录更改为batchfile1所在的位置，然后在完成后更改回来