SetProcessAffinityMask - 选择多个处理器？

Question

如何使用 SetProcessAffinityMask 选择多个逻辑处理器？

在 Windows 任务管理器中，您可以执行此操作作为示例：

我更新了我的 CreateProcess 过程来执行此操作：

type
  TProcessPriority = (ptLow         = $00000040,
                      ptBelowNormal = $00004000,
                      ptNormal      = $00000020,
                      ptAboveNormal = $00008000,
                      ptHigh        = $00000080,
                      ptRealtime    = $00000100);

procedure RunProcess(FileName: string; Priority: TProcessPriority);
var
  StartInfo: TStartupInfo;
  ProcInfo: TProcessInformation;
  CmdLine: string;
  Done: Boolean;
begin
  FillChar(StartInfo, SizeOf(TStartupInfo), #0);
  FillChar(ProcInfo, SizeOf(TProcessInformation), #0);
  StartInfo.cb := SizeOf(TStartupInfo);

  CmdLine := FileName;
  UniqueString(CmdLine);
  try
    Done := CreateProcess(nil, PChar(CmdLine), nil, nil, False,
                          CREATE_NEW_PROCESS_GROUP + Integer(Priority),
                          nil, nil, StartInfo, ProcInfo);
    if Done then
    begin
      // Todo: Get actual cpu core count before attempting to set affinity!
      // 0 = <All Processors>
      // 1 = CPU 0
      // 2 = CPU 1
      // 3 = CPU 2
      // 4 = CPU 3
      // 5 = CPU 5
      // 6 = CPU 6
      // 7 = CPU 6
      // 8 = CPU 7

      // this sets to CPU 0 - but how to allow multiple parameters to
      // set more than one logical processor?
      SetProcessAffinityMask(ProcInfo.hProcess, 1); 
    end else
      MessageDlg('Could not run ' + FileName, mtError, [mbOk], 0)
  finally
    CloseHandle(ProcInfo.hProcess);
    CloseHandle(ProcInfo.hThread);
  end;
end;

请注意我在那里添加的注释。最好更新我的过程以包含一个新的 Affinity 参数，我可以将其传递给 SetProcessAffinityMask。

出于显而易见的原因，调用其中任何一个都不会选择相应的处理器，它们给出了我想要执行的操作的想法：

SetProcessAffinityMask(ProcInfo.hProcess, 1 + 2); 
SetProcessAffinityMask(ProcInfo.hProcess, 1 and 2);

例如，为进程选择任何 CPU，如任务管理器中所示。

我应该如何使用数组、集合或其他东西来做到这一点？我无法让它与多个值一起工作。

谢谢。

Answer 1

它是一个位掩码，如文档中所述。

进程关联掩码是一个位向量，其中每个位代表一个允许运行进程线程的逻辑处理器。

• 处理器 0 是 $01。
• 处理器 1 的价格为 02 美元。
• 处理器 2 的价格为 04 美元。
• 处理器 3 的售价为 08 美元。
• 处理器 4 售价 10 美元。

等等。您可以使用逻辑或来组合它们。因此处理器 0 和 1 将是 $01 或 $02，等于 $03。

我将使用移位运算符 shl 为特定处理器创建值。像这样：

function SingleProcessorMask(const ProcessorIndex: Integer): DWORD_PTR;
begin
  //When shifting constants the compiler will force the result to be 32-bit
  //if you have more than 32 processors, `Result:= 1 shl x` will return
  //an incorrect result.
  Result := DWORD_PTR(1) shl (ProcessorIndex); 
end;

您可以轻松地扩展它，以在循环中使用逻辑 or 生成处理器列表的掩码。

function CombinedProcessorMask(const Processors: array of Integer): DWORD_PTR;
var
  i: Integer;
begin
  Result := 0;
  for i := low(Processors) to high(Processors) do
    Result := Result or SingleProcessorMask(Processors[i]);
end;

您可以测试处理器是否处于位掩码中，如下所示：

function ProcessorInMask(const ProcessorMask: DWORD_PTR; 
  const ProcessorIndex: Integer): Boolean;
begin
  Result := (SingleProcessorMask(ProcessorIndex) and ProcessorMask)<>0;
end;

注意：我使用的是DWORD_PTR，因为对于 64 位目标，位掩码是 64 位宽。这种细微差别对于 XE 上的您来说并不重要，但值得正确对待它以使将来的代码移植更容易。

Answer 2

它在我的 XE 上是 32 位位掩码（但在 64 位 XE2 上可能是 64 位！）

只需定义一组 [0..31]，其中 0=cpu 1 等。

然后将结果键入掩码为双字。

所以

var 
  cpuset  : set of 0..31;

begin
  cpuset:=[1,2]; // cpus 2 and 3
  include (cpuset,5); // add cpu 6
  SetProcessAffinityMask(ProcInfo.hProcess, dword(cpuset));