查找物料/仓库的总可用量和可用实物

Question

我有一个显示字段的方法，它执行以下操作；

return InventSum::find(_salesLine.ItemId, InventDim::_salesLine.InventDimId).AvailPhysical();

这为我提供了该线路站点/仓库/位置的现有可用实物。

我需要查看站点/仓库的可用总数。我想我需要按项目/仓库搜索 inventDim 来获取我的 inventdimid，但我找不到该方法，所以我怀疑这是不正确的。

有人可以帮忙吗？

Answer 1

我的工作解决方案...

InventDimParm       invDimParm;
InventDim           warehouseInvDim;
InventDim           salesLineInventDim;
;

salesLineInventDim = _salesLine.inventDim();

warehouseInvDim.InventSiteId = salesLineInventDim.InventSiteId;
warehouseInvDim.InventLocationId = salesLineInventDim.InventLocationId;

warehouseInvDim = InventDim::findOrCreate(warehouseInvDim);
invDimParm.initFromInventDim(InventDim::find(warehouseInvDim.inventDimId));

return InventSum::findSum(_salesLine.ItemId,warehouseInvDim,invDimParm).availOrdered();

我知道这是针对availOrdered() 但它的工作原理与availPhysical() 完全相同

Answer 2

您应该使用 InventOnhand 类。

它根据商品 ID 和库存尺寸等标准对现有发明值进行求和。

AX有很多用途，搜索Class节点。

Answer 3

以下作业查找所有处于“未结订单”状态的销售行，这些销售行的现有可用实物数量与销售行上指定的所有维度（位置除外）相匹配：

static void FindOpenSalesLineAvailPhys(Args _args)
{
    SalesLine salesline;
    InventDim inventDim;
    InventDimParm inventDimParm;
    InventOnHand inventOnHand;
    ;

    while select salesLine where salesLine.SalesStatus == SalesStatus::Backorder
    {
        inventDim = salesLine.inventDim();
        inventDimParm.initFromInventDim(inventDim);
        inventDimParm.WMSLocationIdFlag = NoYes::No;
        inventOnHand = InventOnHand::newItemDim(salesLine.ItemId, inventDim, inventDimParm);
        if (inventOnHand.availPhysical())
        {
            info(strfmt("Sales Order %1 Line %2 Item Id %3 Available Physical (ignoring Location) %4",
                salesLine.salesId, salesLine.LineNum, salesLine.ItemId, inventOnHand.availPhysical()));
        }
    }
}

Answer 4

您基本上按照要搜索的方式设置 inventDim 值，然后执行 InventDim::FindOrCreate 来查看库存维度是否已存在，或者需要创建它并使用新的编号规则。使用它是为了使 InventDim 表不会存储所有可能的维度组合。另外，因为如果您有任何序列化产品，则该表不可能存储所有组合，因此它只存储它需要的组合。

InventDim   inventDim;
SalesLine   _salesLine;
;

inventDim.InventSiteId      = 'mySite';
inventDim.InventLocationId  = 'myWarehouse';
inventDim   = InventDim::findOrCreate(inventDim);

return InventSum::find(_salesLine.ItemId, inventDim.inventDimId).AvailPhysical();