对 VB6 中的错误处理和 On Error GoTo 的使用感到困惑

Question

我需要对一些旧的 VB6 代码进行故障排除，但我对“On Error”的使用感到困惑。在下面的示例中，如果我围绕要使用 On Error GoTo 和 ErrHandler1 进行测试的特定代码行，则这是唯一经过测试的行。或者如果它在同一个子中，除以零是否会被包括在内？

On Error GoTo ErrHandler1
If Not Exists(BaseDirectory + "\ARCHIVE") Then _
   MkDir BaseDirectory + "\ARCHIVE"

ErrHandler1:
   Call MsgBox(Err.Number & vbCrLf & Err.Description, vbExclamation, App.Title)


intValue1 = 12
intValue2 = 0
intValue3 = intValue1 / intValue

谢谢。

Answer 1

除以零将被包含并处理，它可能会在您的示例中创建一个循环......

正确的方法是这样的

On Error GoTo ErrHandler1
If Not Exists(BaseDirectory + "\ARCHIVE") Then _
   MkDir BaseDirectory + "\ARCHIVE"

On Error Goto 0 'this will un-hook you error handler

intValue1 = 12
intValue2 = 0
intValue3 = intValue1 / intValue  'this will be an un-managed error

Exit Sub 'this make sure that msgbox is shown only when the error happens

ErrHandler1:
   Call MsgBox(Err.Number & vbCrLf & Err.Description, vbExclamation, App.Title)

Answer 2

仅当 MkDir 不会导致抛出错误时才会处理除以零。

也就是说，它将循环到 ErrHandler1 标签，并且再次除以零时将生成另一个错误，该错误将不会被处理，因为您无法将错误处理嵌套在另一个错误处理程序中。

因此，该代码就其本身而言没有意义，错误处理程序应进一步移至代码下方（在退出子下方），以确保它只被调用一次：

On Error Goto ErrHandler1

    'some code

    exit sub
ErrHandler1:
    msgbox "There was an error"

如果您想分别处理这两个操作，您可以这样做：

On Error GoTo ErrHandler1
If Not Exists(BaseDirectory + "\ARCHIVE") Then _
   MkDir BaseDirectory + "\ARCHIVE"

DoCalc:
    On Error GoTo Errhandler2
    intvalue1 = 12
    intvalue2 = 0
    intvalue3 = intvalue1 / intvalue

    Exit Sub

ErrHandler1:
   Call MsgBox("Error making directory - " & Err.Number & vbCrLf & Err.Description, vbExclamation, App.Title)
   Resume DoCalc:

Errhandler2:
    Call MsgBox("Error doing arithmetic - " & Err.Number & vbCrLf & Err.Description, vbExclamation, App.Title)

Answer 3

位于过程顶部的 GoTo 错误处理程序是良好的编程风格，对于大多数过程来说应该是最少的错误处理量。然而，它不如在可能导致错误的代码行之后检查错误灵活。在相当简单的过程中添加错误处理时，我使用 On Error GoTo ... 语句和例程底部的捕获所有错误处理程序。

On Error GoTo procErrorHandler

    If Not Exists(BaseDirectory + "\ARCHIVE") Then
        MkDir BaseDirectory + "\ARCHIVE"
    End If

    intvalue1 = 12
    intvalue2 = 0
    intvalue3 = intvalue1 / intvalue

ProcExit:
    Exit Sub

procErrorHandler:
    Call MsgBox("There was an error in the procedure. Error " & CStr(Err.Number) & ", " & Err.Description, vbExclamation, App.Title)
    Resume ProcExit  ' A chance to do any cleanup needed

我不喜欢多个 GoTo 语句，因为它使代码难以阅读和遵循。在一个过程中，我正在执行多个步骤，并且我想返回一个错误来更准确地描述代码出错的位置，或者在我可能有机会从错误中恢复并继续的情况下，我禁用了包罗万象的功能错误处理类型并在关键步骤后检查 Err.Number 属性。如果我修改 Matt 的错误处理，我会以这种方式编写过程。

On Error Resume Next

    If Not Exists(BaseDirectory + "\ARCHIVE") Then
        MkDir BaseDirectory + "\ARCHIVE"
    End If
    ' check for errors making the directory
    If Err.Number <> 0 Then
        Call MsgBox("Error making directory - " & Err.Number & vbCrLf & Err.Description, vbExclamation, App.Title)
    End If

    intvalue1 = 12
    intvalue2 = 0
    intvalue3 = intvalue1 / intvalue
    ' check for errors getting intvalue3
    If Err.Number <> 0 Then
        Call MsgBox("Error doing arithmetic - " & Err.Number & vbCrLf & Err.Description, vbExclamation, App.Title)
    End If

Exit Sub