对目标类型的子项进行策略性抽象

Question

作为一个粗略且未经训练的背景，在 HoTT 中，人们从归纳定义的类型中推断出

Inductive paths {X : Type } : X -> X -> Type :=
 | idpath : forall x: X, paths x x.

它允许非常一般的

Lemma transport {X : Type } (P : X -> Type ){ x y : X} (γ : paths x y):
  P x -> P y.
Proof.
 induction γ.
 exact (fun a => a).
Defined.

构造引理传输将是HoTT“替换”或“重写”策略的核心；据我所知，诀窍是，假设你或我可以抽象地认识到一个目标，即

...
H : paths x y
[ Q : (G x) ]
_____________
(G y)

找出必要的依赖类型 G，以便我们可以应用（传输 GH）。到目前为止，我发现这

Ltac transport_along γ :=
match (type of γ) with 
| ?a ~~> ?b =>
 match goal with
 |- ?F b => apply (transport F γ)
 | _ => idtac "apparently couldn't abstract" b "from the goal."  end 
| _ => idtac "Are you sure" γ "is a path?" end.

还不够普遍。也就是说，第一个idtac 使用得相当频繁。

问题是

[有没有|什么是]正确的做法？

Answer 1

关于对类型中的关系使用重写，存在一个 bug，这会允许你只说rewrite <- y.

同时，

Ltac transport_along γ :=
  match (type of γ) with 
    | ?a ~~> ?b => pattern b; apply (transport _ y)
    | _ => idtac "Are you sure" γ "is a path?"
  end.

可能会做你想做的事情。

Answer 2

Tom Prince 在他的回答中提到的功能请求已获得批准：

Require Import Coq.Setoids.Setoid Coq.Classes.CMorphisms.
Inductive paths {X : Type } : X -> X -> Type :=
| idpath : forall x: X, paths x x.

Lemma transport {X : Type } (P : X -> Type ){ x y : X} (γ : paths x y):
  P x -> P y.
Proof.
  induction γ.
  exact (fun a => a).
Defined.

Global Instance paths_Reflexive {A} : Reflexive (@paths A) := idpath.
Global Instance paths_Symmetric {A} : Symmetric (@paths A).
Proof. intros ?? []; constructor. Defined.

Global Instance proper_paths {A} (x : A) : Proper paths x := idpath x.
Global Instance paths_subrelation
       (A : Type) (R : crelation A)
       {RR : Reflexive R}
  : subrelation paths R.
Proof.
  intros ?? p.
  apply (transport _ p), RR.
Defined.
Global Instance reflexive_paths_dom_reflexive
       {B} {R' : crelation B} {RR' : Reflexive R'}
       {A : Type}
  : Reflexive (@paths A ==> R')%signature.
Proof. intros ??? []; apply RR'. Defined.

Goal forall (x y : nat) G, paths x y -> G x -> G y.
  intros x y G H Q.
  rewrite <- H.
  exact Q.
Qed.

我通过比较获得的日志找到了所需的实例当 H : paths x y 和当 H : eq x 时，从 setoid_rewrite <- H 设置类型类调试 y 。