CoffeeScript 和 Backbone.js 未捕获的类型错误

Question

Rails 应用程序，学习 CoffeeScript 和 Backbone.js：

Uncaught TypeError: Cannot use 'in' operator to search for 'id' in easy
_.extend.setbackbone.js:205
Backbone.Modelbackbone.js:142
Gamegames.js:13
(anonymous function)games.js:34
jQuery.Callbacks.firejquery.js:1047
jQuery.Callbacks.self.fireWithjquery.js:1165
jQuery.extend.readyjquery.js:436
DOMContentLoadedjquery.js:924

这是代码，games.js.coffee

jQuery ->
  root = global ? window
  class Game extends Backbone.Model
    initialize: (@n, @diff) ->
      console.log "--> Game.initialize()"
    difficulty: ->
      @diff
    name: ->
      @n
  # Make class Game globally available
  root.Game = Game
  my_game = new Game('easy', 'hard')
  console.log "my_game.name(), my_game.difficulty() --> #{my_game.name()}, #  {my_game.difficulty()}"

我遗漏了一些东西，但无法弄清楚什么......

Answer 1

主干模型构造函数需要一个字典对象，其中包含将在该模型上设置的键和值。您没有提供对象，而是提供了 2 个字符串。该错误是由主干尝试迭代对象引起的，但由于无法合法地执行 for (key in "easy") 而导致爆炸。

您也不应该使用模型数据的属性。您应该在实例化或 set() 和 get() 上使用对象。因此，如果我可以更正您的代码：

jQuery ->
  root = global ? window
  class Game extends Backbone.Model
    initialize: ->
      console.log "--> Game.initialize()"
    difficulty: ->
      @get 'diff'
    name: ->
      @get 'n'
  # Make class Game globally available
  root.Game = Game
  my_game = new Game n: 'easy', diff: 'hard'
  console.log "my_game.name(), my_game.difficulty() --> #{my_game.name()}, #{my_game.difficulty()}"

请参阅此处的示例： http://jsfiddle.net/NMkna/

请注意我们现在如何不再接受初始化中的参数。我们可以依靠backbone在模型中设置适当的属性，因为我们现在在创建游戏时传入一个对象。我们简单地定义@get 'propname' 方法来检索这些值。