使用 Moose 进行对象组合的最佳方法是什么？

Question

只是关于驼鹿最佳实践的初学者问题：

从简单的“点”示例开始，我想构建一个“线”对象，由两个点组成并具有长度属性，描述起点和终点之间的距离。

{
  package Point;
  use Moose;

  has 'x' => ( isa => 'Int', is => 'rw' );
  has 'y' => ( isa => 'Int', is => 'rw' );
}

{
  package Line;
  use Moose;

  has 'start' => (isa => 'Point', is  => 'rw', required => 1, );
  has 'end' => (isa => 'Point', is  => 'rw', required => 1, );
  has 'length' => (isa => 'Num', is => 'ro', builder => '_length', lazy => 1,);

  sub _length {
    my $self = shift;
    my $dx = $self->end->x - $self->start->x;
    my $dy = $self->end->y - $self->start->y;
    return sqrt( $dx * $dx + $dy * $dy );
  }
}

my $line = Line->new( start => Point->new( x => 1, y => 1 ), end => Point->new( x => 2, y => 2 ) );
my $len = $line->length;

上面的代码按预期工作。 现在我的问题是：

• 这是解决问题/进行简单对象组合的最佳方法吗？

• 是否有另一种方法可以用这样的东西创建行（示例不起作用！）（顺便说一句：确实存在哪些其他方法？）：

>

my $line2 = Line->new( start->x => 1, start->y => 1, end => Point->new( x => 2, y => 2 ) );

• 当坐标更改时如何触发自动重新计算长度？或者拥有像长度这样可以“轻松”从其他属性派生的属性没有意义吗？这些值（长度）是否最好作为函数提供？

>

$line->end->x(3);
$line->end->y(3);
$len = $line->length;

• 我怎样才能使这样的事情成为可能？立即更改点的方法是什么 - 而不是更改每个坐标？

>

$line2->end(x => 3, y =>3);

感谢您的任何答复！

Answer 1

这是解决简单对象问题的最佳方法吗
组成？

在不知道你要做什么的情况下回答这个问题太主观了，而且问题也过于简单化。但我可以说你所做的没有任何问题。

我要做的更改是将计算两点之间距离的工作移至 Point 中。然后其他人就可以利用。

# How do I do something like this?
my $line2 = Line->new(
    start->x => 1, start->y => 1,
    end => Point->new( x => 2, y => 2 )
);

我要注意的第一件事是，通过前面的对象，您不会节省太多打字时间......但就像我说的，这是一个简单的示例，所以让我们假设创建对象是乏味的。有很多方法可以得到你想要的，但一种方法是编写 BUILDARGS 转换参数的方法。手册中的示例有点奇怪，这里有一个更常见的用法。

# Allow optional start_x, start_y, end_x and end_y.
# Error checking is left as an exercise for the reader.
sub BUILDARGS {
    my $class = shift;
    my %args = @_;

    if( $args{start_x} ) {
        $args{start} = Point->new(
            x => delete $args{start_x},
            y => delete $args{start_y}
        );
    }

    if( $args{end_x} ) {
        $args{end} = Point->new(
            x => delete $args{end_x},
            y => delete $args{end_y}
        );
    }

    return \%args;
}

还有第二种方法可以通过类型强制来实现，这在某些情况下更有意义。请参阅下面关于如何执行 $line2->end(x => 3, y =>3) 的答案。

如何在以下情况下触发自动重新计算长度：
坐标改变了？

奇怪的是，有一个触发器！当属性更改时，将调用属性上的触发器。正如@Ether指出的，您可以添加更清晰到length，然后触发器可以调用它来取消设置length。这并不违反 length 是只读的。

# You can specify two identical attributes at once
has ['start', 'end'] => (
    isa             => 'Point',
    is              => 'rw',
    required        => 1,
    trigger         => sub {
        return $_[0]->_clear_length;
    }
);

has 'length' => (
    isa       => 'Num',
    is        => 'ro',
    builder   => '_build_length',
    # Unlike builder, Moose creates _clear_length()
    clearer   => '_clear_length',
    lazy      => 1
);

现在，每当设置 start 或 end 时，它们都会清除 length 中的值，从而在下次调用时重新构建它。

这确实带来了一个问题...如果start和end被修改，length将会改变，但是如果直接改变Point对象会怎样？ $line->start->y(4)?如果您的 Point 对象被另一段代码引用并且他们更改了它怎么办？这些都不会导致长度重新计算。你有两个选择。首先是使 length 完全动态化，这可能成本高昂。

第二种是将Point的属性声明为只读。您无需更改对象，而是创建一个新对象。那么它的值就无法更改，并且您可以安全地缓存基于它们的计算。该逻辑延伸至线和多边形等。

这也使您有机会使用享元模式。如果 Point 是只读的，则每个坐标只需要一个对象。 Point->new 成为一个工厂，要么生成一个新对象，要么返回一个现有对象。这可以节省大量内存。同样，这种逻辑延伸到线和多边形等。

是的，将 length 作为属性确实有意义。虽然它可以从其他数据派生，但您希望缓存该计算。如果 Moose 有一种方法可以显式声明 length 纯粹是从 start 和 end 派生的，因此应该自动缓存和重新计算，那就太好了，但事实并非如此。

我怎样才能使这样的事情成为可能？ $line2->end(x => 3, y => 3);

实现这一点的最简单的方法是使用 类型强制。
您定义一个子类型，它将哈希引用转换为 Point。它是
最好在 Point 中定义它，而不是在 Line 中，以便其他类可以
当他们使用积分时使用它。

use Moose::Util::TypeConstraints;
subtype 'Point::OrHashRef',
    as 'Point';
coerce 'Point::OrHashRef',
    from 'HashRef',
    via { Point->new( x => $_->{x}, y => $_->{y} ) };

然后将 start 和 end 的类型更改为 Point::OrHashRef 并开启强制转换。

has 'start' => (
    isa             => 'Point::OrHashRef',
    is              => 'rw',
    required        => 1,
    coerce          => 1,
);

现在 start、end 和 new 将接受哈希引用并将它们默默地转换为 Point 对象。

$line = Line->new( start => { x => 1, y => 1 }, end => Point->new( x => 2, y => 2 ) );
$line->end({ x => 3, y => 3 ]);

它必须是哈希引用，而不是哈希，因为 Moose 属性仅采用标量。

什么时候使用类型强制以及什么时候使用BUILDARGS？一个好的
经验法则是，如果 new 的参数映射到属性，则使用 type
强迫。然后new并且属性可以一致地起作用，并且其他类可以使用该类型来使它们的Point属性具有相同的行为。

一切都在这里，并进行了一些测试。

{
    package Point;
    use Moose;

    has 'x' => ( isa => 'Int', is => 'rw' );
    has 'y' => ( isa => 'Int', is => 'rw' );

    use Moose::Util::TypeConstraints;
    subtype 'Point::OrHashRef',
      as 'Point';
    coerce 'Point::OrHashRef',
      from 'HashRef',
      via { Point->new( x => $_->{x}, y => $_->{y} ) };

    sub distance {
        my $start = shift;
        my $end = shift;

        my $dx = $end->x - $start->x;
        my $dy = $end->y - $start->y;
        return sqrt( $dx * $dx + $dy * $dy );
    }
}

{
  package Line;
  use Moose;

  # And the same for end
  has ['start', 'end'] => (
      isa             => 'Point::OrHashRef',
      coerce          => 1,
      is              => 'rw',
      required        => 1,
      trigger         => sub {
          $_[0]->_clear_length();
          return;
      }
  );

  has 'length' => (
      isa       => 'Num',
      is        => 'ro',
      clearer   => '_clear_length',
      lazy      => 1,
      default   => sub {
          return $_[0]->start->distance( $_[0]->end );
      }
  );
}


use Test::More;

my $line = Line->new(
    start => { x => 1, y => 1 },
    end   => Point->new( x => 2, y => 2 )
);
isa_ok $line,           "Line";
isa_ok $line->start,    "Point";
isa_ok $line->end,      "Point";
like $line->length, qr/^1.4142135623731/;

$line->end({ x => 3, y => 3 });
like $line->length, qr/^2.82842712474619/,      "length is rederived";

done_testing;

Answer 2

这与其说是驼鹿问题，不如说是面向对象设计问题。但在这些术语中，有一些有趣的事情需要指出：

1. 线具有值语义，这意味着具有不同点的两条线实际上是不同的线。读写点属性对于线没有意义。这些应该是只读属性；如果您需要一条线来包含不同的点，那么实际上您需要一条不同的线。
2. 点，同理。
3. 对于给定的线，其长度是恒定的并且完全可以从其点属性导出。将线的长度作为属性使事情变得复杂：它使得构造不可能的线成为可能，并且（当与读写点属性结合时）打开了一致性错误的大门。让长度成为普通方法更自然，更不易出错。
4. 使用属性支持 length 方法是一种性能优化。与所有优化一样，由此引入的额外复杂性必须通过分析来证明其合理性。

回到驼鹿特定的问题。 Moose 不提供额外的构造函数形式。另一方面，它不会阻止您提供自己的构造函数形式，因此：

sub new_from_coords {
  my ($class, $x1, $y1, X2, $y2) = @_;

  return $class->new(
    start => $class->_make_point($x1, $y1),
    end => $class->_make_point($x2, $y2),
  );
}

sub _make_point {
  my ($class, $x, $y) = @_;

  return Point->new(x => $x, y => $y);
}

my $line = Line->new_from_coords(2, 3, 6, 7);

提供更方便且受约束的构造函数是相当常见的做法。 Moose 的开放式接口非常适合一般情况，但收紧它们是降低整体复杂性的好方法。