驼鹿属性：分离数据和行为

Question

我有一个用 Moose 构建的类，它本质上是文章列表的数据容器。所有属性 - 例如 name、number、price、quantity - 都是数据。 “好吧，还有什么？”，我能听到你说。那么还有什么呢？

现在，不幸情况的邪恶阴谋迫使外部功能进入该包：此类中数据的税收计算必须由外部组件执行。这个外部组件与整个应用程序紧密耦合，包括数据库和依赖项，这些依赖项破坏了组件的可测试性，将其拖入了一切耦合在一起的混乱之中。 （甚至考虑从炖菜中重构税收组件也是完全不可能的。）

所以我的想法是让类接受包装税收计算组件的 coderef。然后，该类将保持独立于税收计算实现（及其可能的依赖噩梦），同时它将允许与应用程序环境集成。

有“tax_calculator”，是 => 'ro', isa =>; '代码引用';

但是然后，我会在我的类中添加一个非数据组件。为什么这是一个问题？因为我（ab）使用 $self->meta->get_attribute_list 为我的类组装数据导出：

my %data; # need a plain hash, no objects
my @attrs = $self->meta->get_attribute_list;
$data{ $_ } = $self->$_ for @attrs;
return %data;

现在 coderef 是属性列表的一部分。当然，我可以过滤掉它。但我不确定我在这里所做的一切是否是一个合理的方式。那么，您将如何处理这个需要分离数据属性和行为属性的问题呢？

Answer 1

一个可能的半深思熟虑的解决方案：使用继承。像今天一样创建您的类，但使用calculate_tax 方法，该方法如果被调用就会终止（即虚拟函数）。然后创建重写该方法的子类以调用外部系统。您可以测试基类并使用子类。

替代解决方案：使用角色添加calculate_tax 方法。您可以创建两个角色：Calculate::Simple::Tax 和Calculate::Real::Tax。在测试时添加简单角色，在生产中添加真实角色。

我编写了这个例子，但我不使用 Moose，所以我可能对如何将角色应用到课堂上感到疯狂。可能还有更多 Moosey 方法可以做到这一点：

#!/usr/bin/perl

use warnings;

{
    package Simple::Tax;
    use Moose::Role;

    requires 'price';

    sub calculate_tax {
        my $self = shift;
        return int($self->price * 0.05);
    }
}


{
    package A;
    use Moose;
    use Moose::Util qw( apply_all_roles );

    has price => ( is => "rw", isa => 'Int' ); #price in pennies

    sub new_with_simple_tax {
        my $class = shift;
        my $obj = $class->new(@_);
        apply_all_roles( $obj, "Simple::Tax" );
    }
}

my $o = A->new_with_simple_tax(price => 100);
print $o->calculate_tax, " cents\n";

看起来在 Moose 中执行此操作的正确方法是使用两个角色。第一个应用于类并包含生产代码。第二个应用于您想要在测试中使用的对象。它使用 around 方法颠覆了第一个方法，并且从不调用原始方法：

#!/usr/bin/perl

use warnings;

{
    package Complex::Tax;
    use Moose::Role;

    requires 'price';

    sub calculate_tax {
        my $self = shift;
        print "complex was called\n";
        #pretend this is more complex
        return int($self->price * 0.15);
    }
}

{
    package Simple::Tax;
    use Moose::Role;

    requires 'price';

    around calculate_tax => sub {
        my ($orig_method, $self) = @_;
        return int($self->price * 0.05);
    }
}


{
    package A;
    use Moose;

    has price => ( is => "rw", isa => 'Int' ); #price in pennies

    with "Complex::Tax";
}

my $prod = A->new(price => 100);
print $prod->calculate_tax, " cents\n";

use Moose::Util qw/ apply_all_roles /;
my $test = A->new(price => 100);
apply_all_roles($test, 'Simple::Tax');
print $test->calculate_tax, " cents\n";

Answer 2

我想到了一些事情：

• 在一个单独的 TaxCalculation 类中实现税收计算逻辑，该类将文章列表和税收计算器作为属性。
• 测试时使用模拟对象作为税收计算器。税收计算器可以存储在默认情况下创建实际税收计算器的属性中。测试传入一个具有相同接口但不执行任何操作的模拟对象。

Answer 3

实际上，这并不是对 get_attribute_list 的滥用，因为这正是 MooseX::Storage 的工作原理[^1]。 如果您要继续使用 get_attribute_list 构建直接数据，您将需要执行 MooseX::Storage 所做的操作并为“DoNotSerialize”[^2] 设置属性特征：

package MyApp::Meta::Attribute::Trait::DoNotSerialize;
use Moose::Role;

# register this alias ...
package Moose::Meta::Attribute::Custom::Trait::DoNotSerialize;

sub register_implementation { 'MyApp::Meta::Attribute::Trait::DoNotSerialize' }

1;
__END__

然后可以在你的类中使用它，如下所示：

has 'tax_calculator' => ( is => 'ro', isa => 'CodeRef', traits => ['DoNotSerialize'] );

在你的序列化代码中，如下所示：

my %data; # need a plain hash, no objects
my @attrs = grep { !$_->does('MyApp::Meta::Attribute::Trait::DoNotSerialize') } $self->meta->get_all_attributes; # note the change from get_attribute_list
$data{ $_ } = $_->get_value($self) for @attrs; # note the inversion here too
return %data;

最终，尽管你最终会得到一个类似于 Chas 提出的角色的解决方案，我刚刚在这里回答了他的后续问题：如何处理 Moose 中的模拟角色？。

希望这有帮助。

[^1]：由于 MooseX::Storage 最基本的用例就是完全按照您所描述的方式进行操作，因此我强烈建议您查看它以手动执行您正在做的事情。

[^2]：或者简单地重复使用 MooseX::Storage 创建的那个。