批量查找目录中其他 .txt 文件中的字符串（包含在 textlist.txt 中）并将值从 .txt 复制到新文件

Question

在查找批处理以查找和复制文本文件中 textlist.txt 中列出的字符串时遇到问题。是否可以使批处理女巫应该找到目录中文本文件中的所有值（来自文本列表）并将所有这些值复制到新文件中。 我的目录包含：

textlist.txt 包含：

• 3010
• 3020
• 3030 ....

以及其他包含 txt 文件的目录：

3010.txt 包含制表符分隔，例如：

• 3010 a1
• 3011 b1
• 3012 c1 ....

3020.txt 包含例如：

• 3020 a4
• 3021 b3
• 3022 g5 ....

3030.txt 包含例如：

• 3030 h5 g7
• 3031 f2
• 3032 t4 ....

以及其他 3040.txt、3050.txt 等。

我需要这样的结果 txt 文件。

• 3010 a1 { 该字符串来自 3010.txt，但可能在其他 txt 文件中找到。}
• 3020 a4 { 该字符串来自 3010.txt，但可能在其他 txt 文件中找到。}
• 3030 h5 g7 {此字符串来自 3010.txt，但可能可以在其他 txt 文件中找到。}

感谢您的帮助。

Answer 1

以下将生成一个文件，其中包含所有输入行的所有文件的匹配项：

@ECHO OFF
>results.txt (
  FOR /F "delims=" %%i IN (textlist.txt) DO (
    FIND "%%i" files\*.txt | FINDSTR /v "^---- ^$"
  )
)

它的工作原理如下：

• FIND 获取输入行，搜索指定的文件并打印结果，其通过管道传输到 FINDSTR。

• FINDSTR 消除了 FIND 产生的“噪音”（空行和像 ------ filename.txt 这样的行）打印其余部分。

• 解析结果打印在标准输出上，整个循环被重定向到results.txt。

如果根据您的评论，您还需要创建另一个包含没有匹配项的行的文件，您可以像这样修改上面的脚本：

@ECHO OFF
>results.txt 2>notinfile.txt (
  FOR /F "delims=" %%i IN (textlist.txt) DO (
    (FIND "%%i" files\*.txt || (ECHO %%i) 1>&2) | FINDSTR /v "^---- ^$"
  )
)

逻辑基本相同，除非 FIND 没有匹配项对于输入线。在这种情况下，搜索词将打印在标准错误上（ECHO … 1>&2）。 FIND 的标准输出仍然通过管道传输到 FINDSTR，并且，因为在这种情况下它只包含噪声，FINDSTR > 什么也不产生。

因此，循环会在标准输出和标准错误上生成结果，每次都取决于 FIND 的结果。标准输出被重定向到 results.txt，就像以前的版本一样，标准错误被重定向到 notinfile.txt。

更新

第二个脚本有一个小缺陷，在您的情况下可能会严重，也可能不严重，具体取决于您将如何使用 notinfile.txt 文件。该缺陷在于在发送到 notinfile.txt 的每个值的末尾添加了一个额外的空格。

我不知道这是一个错误还是某种人工制品，但我发现如果我将 FIND 的结果存储到临时文件中，然后将其加载到 FINDSTR，不会产生额外的空间。我找不到任何其他方法来解决额外的空间问题，所以这里是修改后的版本：

@ECHO OFF
>results.txt 2>notinfile.txt (
  FOR /F "delims=" %%i IN (textlist.txt) DO (
    FIND "%%i" files\*.txt >tmpResults || (ECHO %%i) 1>&2
    FINDSTR /v "^---- ^$" <tmpResults
  )
)
DEL tmpResults 2>NUL

UPDATE 2（以下附加注释）

由于文件中的值是制表符分隔的，因此您可以将分隔符包含到搜索字符串，紧接在搜索词之后，以防止将 aaa 与例如 aaa/bbb 匹配。因此，

FIND "%%i"

%%i 后面的

FIND "%%i   "

宽空格是制表符。

我还想建议 FINDSTR 命令的替代版本。当您只搜索一个术语时，您可以将其更改

FINDSTR /v "^---- ^$"

为简单的：

FINDSTR "%%i"

Answer 2

使用 FOR 命令对文件中的每一行执行命令（使用 /F 开关）。使用 FIND 搜索文件。这是演示其用途的示例。

FIND 报告匹配，但还添加一行以“----”开头的行，以显示在哪个文件中找到匹配项。这就是第一个 FOR 转储到临时文件的原因。第二个 for 将以“-”开头的任何行视为注释，从而从 FIND 中过滤掉该信息。如果您多次运行该批处理，它将删除以前的所有 results.txt 文件。

重要的是，textlist.txt 文件不能与搜索文件夹位于同一文件夹中，否则其内容将包含在结果中。

@echo off
setlocal
set searchFolder=C:\theFolder

del tempResults.txt >nul 2>nul
del results.txt >nul 2>nul

for /F "delims=" %%i in (textlist.txt) do find "%%i" %searchFolder%\*.txt >> tempResults.txt
for /F "delims=" "eol=-" %%i in (tempResults.txt) do echo %%i >>results.txt
del tempResults.txt >nul 2>nul

endlocal