vb.net 专用/重载泛型

Question

我倾向于讨厌代码中的重复，因此当我遇到唯一不同的是类型的问题时，我倾向于使用泛型。来自 C++ 背景，我发现 vb.net 的版本相当令人沮丧，我知道 C++ 有模板专业化，但我猜 vb.net 没有 所以我拥有的是一组例程，无论传递的类型如何，它们都会执行完全相同的代码。

像这样的事情

Public Sub decision(Of T)(ByVal a As T, ByVal b As Integer)
  If b > 10 then
    gt(a)
  Else
    lt(a)
  End If
End Sub

我只传递两种类型给例程，字符串和整数，这些例程对字符串的处理与对整数的处理不同。

Public Sub gt(ByVal a As String)
Public Sub gt(ByVal a As Integer)

Public Sub lt(ByVal a As String)
Public Sub lt(ByVal a As Integer)

这就是我对 vb.net 与 C++ 感到沮丧的地方，据我所知，C++ 会在编译时检查类型，并且仅根据发送的类型进行决策。但是，在 vb.net 中，我收到一个错误，类型 T 无法转换为 String 或 Integer

Error   3   Overload resolution failed because no accessible 'gt' can be called with these arguments:
    'Public Sub gt(a As String)': Value of type 'T' cannot be converted to 'String'.
    'Public Sub gt(a As Integer)': Value of type 'T' cannot be converted to 'Integer'.

我尝试了约束 Public Sub Decision(Of T As {String, Integer})(ByVal a As T, ByVal b As Integer) 但约束必须是可继承类，因此不能使用 String 或 Integer。

我的下一个解决方案是添加 gt 和 lt 的通用版本：

Public Sub lt(Of T)(ByVal a As T)
  Debug.Fail("Not Implemented")
End Sub

Public Sub lt(Of T)(ByVal a As T)
  Debug.Fail("Not Implemented")
End Sub

嘿！不再有编译错误，但是唯一被调用的例程是 gt 和 lt 的通用版本。鉴于之前的无法转换错误，我认为这是有道理的。我以前遇到过这个问题，其中存在通用例程的非通用重载，当时我找不到解决方案，现在也找不到解决方案。

我是否缺少某些东西可以使这种类型的重载成为可能？

编辑：一个完整​​的工作示例

Module Module1
   Sub Main()

      decision(1, 5)
      decision(1, 10)
      decision("hello world", 5)
      decision("hello world", 10)

   End Sub


   Public Sub decision(Of T)(ByVal a As T, ByVal b As Integer)
      If b > 10 Then
         gt(a)
      Else
         lt(a)
      End If
   End Sub

   Public Sub gt(ByVal a As String)
      Debug.WriteLine(" gt string:  " + a)
   End Sub
   Public Sub gt(ByVal a As Integer)
      Debug.WriteLine(" gt integer: " + a.ToString)
   End Sub

   Public Sub lt(ByVal a As String)
      Debug.WriteLine(" lt string: " + a)
   End Sub
   Public Sub lt(ByVal a As Integer)
      Debug.WriteLine(" lt integer: " + a.ToString)
   End Sub

#If False Then
   Public Sub gt(Of T)(ByVal a As T)
      Debug.Fail("Not implemented")
   End Sub
   Public Sub lt(Of T)(ByVal a As T)
      Debug.Fail("Not implemented")
   End Sub
#End If
End Module

Answer 1

来自C++ 模板和 C# 泛型之间的差异（这同样适用于 VB .网）：

C++ 允许编写可能不适用于所有类型参数的代码
模板，然后检查用作类型的特定类型
范围。 C#要求类中的代码要这样写
它可以与任何满足约束的类型一起使用。为了
例如，在 C++ 中，可以编写一个使用以下函数的函数
参数类型对象上的算术运算符 + 和 -
在模板实例化时会产生错误
具有不支持这些运算符的类型。 C# 不允许这样做；
唯一允许的语言结构是那些可以推导的语言结构
不受约束。

我无法使用 .NET 泛型解决您的问题。但是您可以通过使用 lambda 和闭包来避免重复逻辑，我也认为这是在 .NET 中执行此操作的更自然的方式：

Public Sub Decision(ByVal a As String, ByVal b As Integer)
    Decision(b, Sub() gt(a), Sub() lt(a))
End Sub

Public Sub Decision(ByVal a As Integer, ByVal b As Integer)
    Decision(b, Sub() gt(a), Sub() lt(a))
End Sub

Private Sub decision(ByVal b As Integer, ByVal gt As Action, ByVal lt As Action)
    If b > 10 Then
        gt()
    Else
        lt()
    End If
End Sub

Public Sub gt(ByVal a As String)
    Debug.WriteLine(" gt string:  " + a)
End Sub
Public Sub gt(ByVal a As Integer)
    Debug.WriteLine(" gt integer: " + a.ToString)
End Sub

Public Sub lt(ByVal a As String)
    Debug.WriteLine(" lt string: " + a)
End Sub
Public Sub lt(ByVal a As Integer)
    Debug.WriteLine(" lt integer: " + a.ToString)
End Sub