使用 tSQLt 测试时如何回滚事务

Question

我最近正在调用一个代码中包含 rasierror 的过程。 raiserror 位于 try catch 块中。 BEGIN TRAN 也位于 raiserror 之后的同一个 try catch 块中。 Catch 块旨在在事务中发生错误时回滚事务。它执行此操作的方法是检查 @@TRANCOUNT 是否大于 0 我知道它已经启动了一个事务并且需要回滚。使用 tSQLt 进行测试时，@@TRANCOUNT 始终 >0，因此如果它遇到 CATCH 块，则会执行 ROLLBACK 并且 tSQLt 失败（因为 tSQLt 正在事务中运行）。当我发生错误并且运行 CATCH 块时，tSQLt 总是无法通过测试。我无法测试 raiserror 的正确处理。您将如何创建一个可能回滚事务的测试用例？

Answer 1

正如您所提到的，tSQLt 在自己的事务中运行每个测试。要跟踪正在发生的情况，需要在测试完成时同一事务仍然处于打开状态。 SQL Server 不支持嵌套事务，因此您的过程会回滚所有内容，包括框架为当前测试存储的状态信息。此时 tSQLt 只能假设发生了非常糟糕的事情。因此，它将测试标记为错误。

SQL Server 本身不鼓励在过程内进行回滚，如果在打开的事务中调用该过程，则会抛出错误。有关处理这种情况的方法和一些其他信息，请查看我的关于如何回滚的博客文章程序。

Answer 2

当我刚刚阅读 tSQLt 时，这是当我了解事务中运行的每个测试时首先想到的问题之一。由于我的一些存储过程确实启动事务，有些甚至使用嵌套事务，这可能变得具有挑战性。根据我对嵌套事务的了解，如果您应用以下规则，您可以使代码免受持续错误检查的影响，并且仍然可以优雅地处理错误。

• 打开事务时始终使用 TRY/CATCH 块
• 除非引发错误，否则始终提交事务 引发
• 错误时始终回滚事务，除非 @@TRANCOUNT = 0
• 除非完全确定没有打开事务，否则始终重新引发错误在存储过程的开始处。

请牢记这些规则，这里有一个 proc 实现和测试代码的示例来测试它。

ALTER PROC testProc
    @IshouldFail BIT
AS
BEGIN TRY
    BEGIN TRAN

    IF @IshouldFail = 1
        RAISERROR('failure', 16, 1);

    COMMIT
END TRY
BEGIN CATCH
    IF @@TRANCOUNT > 0
        ROLLBACK;

    -- Do some exception handling

    -- You'll need to reraise the error to prevent exceptions about inconsistent 
    -- @@TRANCOUNT before / after execution of the stored proc.
    RAISERROR('failure', 16, 1);
END CATCH
GO


--EXEC tSQLt.NewTestClass 'tSQLt.experiments';
--GO
ALTER PROCEDURE [tSQLt.experiments].[test testProc nested transaction fails]
AS
BEGIN
    --Assemble
    DECLARE @CatchWasHit CHAR(1) = 'N';

    --Act
    BEGIN TRY
        EXEC dbo.testProc 1
    END TRY
    BEGIN CATCH 
        IF @@TRANCOUNT = 0
            BEGIN TRAN --reopen an transaction
        SET @CatchWasHit = 'Y';
    END CATCH

    --Assert
    EXEC tSQLt.AssertEqualsString @Expected = N'Y', @Actual = @CatchWasHit, @Message = N'Exception was expected'

END;
GO

ALTER PROCEDURE [tSQLt.experiments].[test testProc nested transaction succeeds]
AS
BEGIN
    --Act
    EXEC dbo.testProc 0

END;
GO

EXEC tSQLt.Run @TestName = N'tSQLt.experiments'

Answer 3

最好在 BEGIN TRANSACTION 之后使用 BEGIN TRY 块。当我遇到类似问题时我就这样做了。这更符合逻辑，因为在 CATCH 块中我检查了 IF @@TRANCOUNT > 0 回滚。如果在 BEGIN TRANSACTION 之前引发另一个错误，则不需要检查此条件。在这种情况下，您可以测试您的 RAISERROR 功能。

Answer 4

对上述两个答案+1。

但是，如果您不想使用 TRY .. CATCH，请尝试以下代码。 ----- 行之间的部分代表测试，上方和下方代表 tSQLt，在调用您的测试之前和之后。正如您所看到的，无论错误是否发生，tSQLt 在调用测试之前启动的事务仍然存在，正如它所期望的那样。 @@TRANSCOUNT 仍然是 1

您可以注释掉 RAISERROR 来尝试是否引发异常。

SET NOCOUNT ON

BEGIN TRANSACTION  -- DONE BY tSQLt
PRINT 'Inside tSQLt before calling the test: @@TRANCOUNT = ' + CONVERT (VARCHAR, @@TRANCOUNT)

    ---------------------------------
    PRINT '  Start of test ---------------------------'

    SAVE TRANSACTION Savepoint
    PRINT '  Inside the test: @@TRANCOUNT = ' + CONVERT (VARCHAR, @@TRANCOUNT)


    BEGIN TRANSACTION -- PART OF THE TEST
    PRINT '    Transaction in the test: @@TRANCOUNT = ' + CONVERT (VARCHAR, @@TRANCOUNT)

        RAISERROR ('A very nice error', 16, 0)

        PRINT '  @@ERROR = ' + CONVERT(VARCHAR,@@ERROR)


    -- PART OF THE TEST - CLEAN-UP
    IF @@ERROR <> 0 ROLLBACK TRANSACTION Savepoint   -- Not all the way, just tothe save point
    ELSE COMMIT TRANSACTION

    PRINT '  About to finish the test: @@TRANCOUNT = ' + CONVERT (VARCHAR, @@TRANCOUNT)

    PRINT '  End of test ---------------------------'

    ---------------------------------

ROLLBACK TRANSACTION   -- DONE BY tSQLt
PRINT 'Inside tSQLt after finishing the test: @@TRANCOUNT = ' + CONVERT (VARCHAR, @@TRANCOUNT)

感谢 http://www.blackwasp.co.uk/SQLSavepoints.aspx< 中的信息和代码/a>