使用另一个哈希值定义一个哈希值。

Question

有没有办法在仅使用一种数据结构的情况下执行以下操作？

my %hash = (
  "key1" => "value1",
  "key2" => "value2",
  "key3" => $hash{key1},
);

所以基本上，我想将哈希的键值设置为另一个键值。我已经尝试了上述语法，但收到以下警告：

Global symbol "%hash" requires explicit package name at ...

我假设这是因为我试图在实际创建哈希之前引用它。

Answer 1

这是因为，在使用 $hash{key1} 时，符号“hash”尚未添加到符号表中。您的包还不知道 %hash 是什么，因为直到解析结束的“)”之后它才会被添加到符号表中 - 但它会遇到前面 1 行的符号。

您需要提前预先声明％hash：

my %hash;

%hash = (
  "key1" => "value1",
  "key2" => "value2",
  "key3" => $hash{key1},
);

但是，虽然上面的代码可以编译，但是它不会按预期工作，因为尚未将任何内容分配给％hash $hash{key1} 被评估。您需要首先将其作为单独的语句进行分配：

my %hash;

%hash = (
  "key1" => "value1",
  "key2" => "value2",
);

%hash = %hash, (
  "key3" => $hash{key1},
); # Or simply $hash{key3} = $hash{key1};

请注意，上面仅将key1中的值复制到key3一次。此后它们就不再有任何联系/关联。如果您想为 key1 和 key3 起别名（例如让它们指向相同的值，而不是包含该值的副本），则此是可能的，但并非那么微不足道。您需要将其放入绑定哈希并编写自定义绑定处理程序以使其正确，或者让每个键的值成为引用。

Answer 2

如果您希望 $hash{key1} 成为 $hash{key3} 的别名，那么可以使用 数据::别名。

use Data::Alias;

my %hash = (
    key1 => 'value1',
    key2 => 'value2'
);

alias $hash{key3} = $hash{key1};

$hash{key1} 和 $hash{key3} 现在将引用单个值，并且对一个值的更新将在另一个值中可见。

Answer 3

您可以使用核心模块 Hash::Util 访问低级 hv_store 例程，该例程可以将哈希值别名在一起。它看起来不像使用 Data::Alias 那样干净，但它已经安装了。

use Hash::Util 'hv_store';

my %hash = (
  key1 => "value1",
  key2 => "value2",
);

hv_store %hash, key3 => $hash{key1};

say "$_: $hash{$_}" for sort keys %hash;
# key1: value1
# key2: value2
# key3: value1

$hash{key1} = 'new value';

say "$_: $hash{$_}" for sort keys %hash;
# key1: new value
# key2: value2
# key3: new value

如果您不希望别名在初始赋值之后持续存在，那么您可以

$hash{key3} = $hash{key1}

在初始声明之后编写以下行：并跳过使用 hv_store。

Answer 4

为什么不创建自己的函数：

use strict;
use warnings;

sub make_hash (@) { 
    my %h;
    my @unresolved;
    while ( @_ ) {
        my ( $key, $value ) = splice( @_, 0, 2 );
        next unless defined $value;
        if (   not ref( $value ) 
           and my ( $ref ) = $value =~ /^ref:\s*(.*\S)\s*$/ 
           ) {
            if ( defined( my $v = $h{ $ref } )) {
                $h{ $key } = $v;
            }
            else {
                push @unresolved, [ $key, $ref ];
            }
        }
        else {
            $value =~ s/^lit://;
            $h{ $key } = $value;
        }
    }
    $h{ $_->[0] } = $h{ $_->[1] } foreach grep { exists $h{ $_->[0] }; } @unresolved;
    return wantarray ? %h : \%h;
} 

为了演示一些功能：

my %hash 
    = make_hash(
      'key1' => 'value1'
    , 'key2' => 'value2'
    , 'key3' => 'ref:key1'
    , 'key4' => 'lit:ref:key2'
    , 'key5' => 'lit:lit:ref:key3'
    );

lit: 前缀涵盖了“如果我真的想要传递一个非-reference as 'ref:so-and-so'? 它在回答时也是递归的，“如果我非常需要创建一个值 'lit:xzy' 怎么办？

我已经做到了这一点，并且我还祝福对 Lit 类或类似内容的传递数据的引用。

sub Ref ($) { bless \shift, 'Ref' }

然后在 make_hash 例程中，您只需检查 ref( $value ) eq 'Ref' 即可。并像下面这样指定它：

my %hash 
    = make_hash(
      'key1' => 'value1'
    , 'key2' => 'value2'
    , 'key3' => Ref 'key1'
    );

有很多方法可以让 Perl 表现得像你希望的那样。

Answer 5

创建要分配给哈希的值列表时，%hash 不包含任何内容，因为您尚未将该列表分配给哈希。

事实上，在创建要分配给散列的值列表时，%hash 并不存在，因为分配先评估其右侧，然后再评估其左侧。这就是为什么你会收到严格错误。

您可能喜欢的一些解决方案：

my %hash = (
  key1 => "value1",
  key2 => "value2",
  key3 => "value1",
);


my $value1 = "value1";
my %hash = (
  key1 => $value1,
  key2 => "value2",
  key3 => $value1,
);


my %hash = (
  ( map { $_ => "value1" } qw( key1 key3 ) ),
  key2 => "value2",
);

Answer 6

您可以说

my %h; 
my $i = 0;
while (
    my ( $k, $v ) = ( 
        key1 => '"value1"',
        key2 => '"value2"',
        key3 => '$h{key1}',
    )[ $i, $i + 1 ] 
  )
{
    $h{$k} = eval $v; 
    $i += 2;
}

只要引用的任何键在引用之前出现在列表中即可。