批处理语法 For Loop If Exists

Question

尝试创建批处理以将 .WTV 文件转换为 mpg 文件。我想每晚运行一次下面的代码来转换每日录制内容以在我的媒体服务器上使用。我关心语法的部分是 for 循环行。我只想在尚未转换和移动的文件上运行脚本。如果发生错误，我无法删除原始文件。最后一个移动循环是获取第一次尝试时无法移动的所有文件。

输入文件看起来像： show.wtv

文件中的输出是 show.wtv.mpg （我同意）

我不知道如何编写 for 循环以获得所需的功能。任何帮助表示赞赏。

最初的想法来自 http://ireckon.net/ 2009/10/converting-wtv-to-mpg-in-windows-7/

@echo off

set recordedtv="D:\Recorded TV\"
set destfolder="D:\Videos\Recorded TV\"
set ffmpeg="D:\TV Converter\FFMPEG\ffmpeg.exe"
set wtvconv="C:\Windows\ehome\WTVConverter.exe"

for %%f in (%recordedtv%*.wtv) Do If Not Exist "%destfolder%%%f.mpg" (
%wtvconv% "%%f" "%%f.dvr-ms"
%ffmpeg% -y -i "%%f.dvr-ms" -vcodec copy -acodec copy -f dvd "%%f.mpg"
del "%%f.dvr-ms"
move "%%f.mpg" %destfolder%
)

for %%f in (%recordedtv%*.mpg) Do move "%%f" %destfolder%

更新：最终使用了这个

@echo off

set "recordedtv=D:\Recorded TV\"
set "destfolder=D:\Videos\Recorded TV\"
set ffmpeg="D:\TV Converter\FFMPEG\ffmpeg.exe"
set wtvconv="C:\Windows\ehome\WTVConverter.exe"

for %%f in ("%recordedtv%*.wtv") do If Not Exist "%destfolder%%%~nxf.mpg" (
%wtvconv% "%%f" "%%f.dvr-ms"
%ffmpeg% -y -i "%%f.dvr-ms" -vcodec copy -acodec copy -f dvd "%%f.mpg"
del "%%f.dvr-ms"
move "%%f.mpg" "%destfolder%"
)

for %%f in ("%recordedtv%*.mpg") Do move "%%f" "%destfolder%"

Answer 1

如果您计划将其他部分添加到存储在变量中的路径，请不要存储带有引号的路径。只需保留双引号或像这样放置它们：

...
set "recordedtv=D:\Recorded TV\"
set "destfolder=D:\Videos\Recorded TV\"
...

这样您就可以将路径与名称/掩码连接起来，而不会导致语法错误。 ，您的路径不是用双引号分隔的，因此您需要根据需要在评估它们的位置对它们进行分隔，因此，例如，for 循环将如下所示：

for %%f in ("%recordedtv%*.wtv") do ...
...
for %%f in ("%recordedtv%*.mpg") do ...

请注意 其他地方也是如此。例如，在脚本中的 move 命令中，目标路径也必须被分隔：

move "%%f.mpg" "%destfolder%"

至于文件存在性检查，这是通过 if exit 命令完成的

if exist target_file (
...    // do whatever you need to do in case the file exists
)

： target_file 位可以是文件、掩码或目录（在后一种情况下，它应以 \ 结尾）。

更新

我想我现在可以看到您的脚本存在一个特定问题。这部分

for %%f in (%recordedtv%*.wtv) Do If Not Exist "%destfolder%%%f.mpg"

是错误的，因为它将目标文件夹和 .wtv 文件的完整路径放在一起，并将生成的字符串用作单个路径。因此 "%destfolder%%%f" 的计算结果如下：

"D:\Videos\Recorded TV\D:\Recorded TV\somename.wtv.mpg"

我只是不确定额外的引号，但这不是这里的重点。我想你已经看到了主要问题。要解决此问题，您只需从 D:\Recorded TV\somename.wtv.mpg 中提取文件名和扩展名，这是使用组合的 ~nx 说明符完成的（ n 代表“名称”，x 代表“扩展名”）：（

for %%f in ("%recordedtv%*.wtv") Do If Not Exist "%destfolder%%%~nxf.mpg"

请注意，存储文件夹路径时仍应不使用双引号，以便正确评估它们复杂的表达方式。）