QML - 启动时主窗口位置（屏幕中心）

Question

我可以如何执行以下操作：我想在中央屏幕上显示我的主窗口。

Answer 1

如果使用 QtQuick，可以这样做：

import QtQuick 2.2
import QtQuick.Controls 1.1
import QtQuick.Window 2.0

ApplicationWindow {
    visible: true
    width: 320
    height: 480
    Component.onCompleted: {
        // Commenting this to use properties instead of setters
        //setX(Screen.width / 2 - width / 2);
        //setY(Screen.height / 2 - height / 2);
        x = Screen.width / 2 - width / 2
        y = Screen.height / 2 - height / 2
    }
}

Answer 2

迪尔森的答案要好得多，特别是因为没有提到小部件......无论如何，这是他的答案的一个更简单的版本：

import QtQuick 2.0
import QtQuick.Window 2.0

Window {
    visible: true
    x: Screen.width / 2 - width / 2
    y: Screen.height / 2 - height / 2
    width: 320
    height: 480
}

---

正如亚历山大提到的，这种绑定可能会导致奇怪的调整大小行为。因此，最好使用迪尔森的答案。我唯一要提到的是，在 QML 中使用 setter 并不常见；例如，某些系统（我相信它们被称为属性拦截器）甚至依赖于设置的属性来执行动画。所以比较常见的做法如下：

import QtQuick 2.0
import QtQuick.Window 2.0

Window {
    visible: true
    width: 320
    height: 480

    Component.onCompleted: {
        x = Screen.width / 2 - width / 2
        y = Screen.height / 2 - height / 2
    }
}

Answer 3

在检查了这两个回复并使用 Qt 5.9.1 实际调试代码后，它显示了原始回复的多个问题：

1. 无法将 [x, y] 绑定到 [width, height] 除非我们想看到调整大小的奇怪效果。
2. 尽管 Component.onCompleted 中的 [x, y] 更改似乎是合乎逻辑的，但它在 2 个不同 DPI 的显示器上无法按预期工作（如我当前开发的系统）。
3. 需要使用 Window.screen 而不是 Screen 单例类型。这样我们就可以得到与窗口匹配的实际屏幕。
4. 为了将 [x, y] 与动态值完全解开，但在初始窗口显示时显示实际窗口屏幕，我们现在使用 onScreenChanged，它是 screen 属性的处理程序改变。

这个解决方案更完整，使用 Window.screen 属性：

ApplicationWindow {
    id: window
    property bool screenInit: false

    title: qsTr("App Window Positioning")
    visible: true

    height: Theme.windowHeight // initial
    width: Theme.windowWidth   // initial

    Connections {
        target: window
        onScreenChanged: if (!screenInit) {
            // we have actual screen delivered here for the time when app starts
            screenInit = true
            window.x = screen.width / 2 - Theme.windowWidth / 2
            window.y = screen.height / 2 - Theme.windowHeight / 2
        }
    }
}

PS 如果是这样，我使用了从 Window 派生的 ApplicationWindow 类型，它应该与 Window 定位行为一致。

Answer 4

缺少所有其他答案来考虑屏幕定位，可能导致窗口显示在错误的屏幕上。也许这曾经适用于以前版本的 Qt，但它似乎不再适用于最新的 Qt 版本。

以下解决方案适用于具有不同 DPI 设置的多屏幕（需要 Qt 5.9 或更高版本；在 macOS 上使用 Qt 5.15 进行测试）：

import QtQuick 2.9
import QtQuick.Window 2.9

Window {
    id: root
    visible: true
    width: 320
    height: 480

    Component.onCompleted: {
        root.x = root.screen.virtualX + root.screen.width / 2 - root.width / 2;
        root.y = root.screen.virtualY + root.screen.height / 2 - root.height / 2;
    }
}

Answer 5

您需要 setGeometry在显示它之前在您的顶级小部件上添加 。我能想到的计算出您需要的几何图形的最简单方法是通过 <代码>QDesktopWidget。尝试下面的示例（创建一个 QPushButton，在各个屏幕上移动小部件时按下它），您就会明白我的意思：

MainWindow::MainWindow(QWidget *parent) :
  QMainWindow(parent),
  ui(new Ui::MainWindow)
{   
  ui->setupUi(this);
  connect(ui->pushButton, SIGNAL(released()), this, SLOT(ButtonPressed()));
}

MainWindow::~MainWindow()
{
  delete ui;
}

void MainWindow::ButtonPressed()
{
  qDebug() << QApplication::desktop()->screenCount();
  qDebug() << QApplication::desktop()->screenNumber();
  qDebug() << QApplication::desktop()->screenGeometry(this);
}

从那里应该相当简单地提出一个有效的通用版本用户的中心屏幕（如果存在）。

Answer 6

亚历山大的回答几乎已经足够好了。但是，在 KDE 上，我观察到以下行为：窗口首先在监视器 1 上打开，然后立即移动到监视器 2。在这种情况下，引用的答案始终强制窗口到监视器 1。

因为尝试检测此行为可能会需要相当多的代码，我只是通过使用计时器寻求一个简单的解决方案：

ApplicationWindow {
  id: window

  visible: true
  height: 320
  width: 480

  function setCoordinates() {
    x += screen.width / 2 - width / 2
    y += screen.height / 2 - height / 2
  }

  Timer {
    id: timer
    running: true
    repeat: false
    interval: 10
    onTriggered: {
      window.setCoordinates();
    }
  }
}

这会在等待 10 毫秒后设置窗口的坐标（希望在这段时间 DE 已经完成其工作）。