如何将 xml 属性的值映射到其他一些值

Question

我有一个类似于以下内容的 XML 文件：

<a>
  <b value="a123" />
  <b value="b234" />
  <b value="c345" />
</a>

我需要将属性映射到其他值。例如，我想将 a123 替换为 q999，将 b234 替换为 z998 和 c345 > 与u997。使用 XSLT 是否可以有效地进行此类转换？映射本身是生成的，因此我可以将其转换为几乎任何格式。现在，假设它是以下 XML 文件：

<map>
  <item from="c345" to="u997" />
  <item from="b234" to="z998" />
  <item from="a123" to="q999" />
</map>

也许有比 XSLT 更好的工具来执行此类转换？目前我只是通过该文件多次 sed 。显然，这个解决方案效率极低，而且根本无法扩展。

Answer 1

就这么简单：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <my:map>
   <map>
    <item from="c345" to="u997" />
    <item from="b234" to="z998" />
    <item from="a123" to="q999" />
   </map>
 </my:map>

 <xsl:variable name="vMap" select=
  "document('')/*/my:map/*/*"/>

 <xsl:template match="node()|@*">
   <xsl:copy>
     <xsl:apply-templates select="node()|@*"/>
   </xsl:copy>
 </xsl:template>

 <xsl:template match=
 "@value[. = document('')/*/my:map/*/*/@from]">
  <xsl:attribute name="value">
   <xsl:value-of select="$vMap[@from = current()]/@to"/>
  </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<a>
    <b value="a123" />
    <b value="b234" />
    <b value="c345" />
</a>

生成所需的正确结果：

<a>
   <b value="q999"/>
   <b value="z998"/>
   <b value="u997"/>
</a>

解释< /strong>:

1. 覆盖身份模板 对于 value 属性whos 值等于地图中的 from 属性。

2. 地图在转换中内联显示，并使用进行访问document() 函数。或者，包含地图的文件的文件路径可以作为外部参数传递给转换，并且可以再次使用 document() 函数，将此文件路径作为参数传递给它。