如何使用 ANTLRWorks 创建/指定用于测试树语法的 AST 输入？

Question

背景：我创建了一个 ANTLR 语法。我能够使用 ANTLRWorks 对其进行测试和调试，并验证解析器是否创建了我心中的 AST。现在，我想为 AST 编写一个树语法，解析该树并使用 ANTLRWorks 调试该树语法。

问题：我想使用 ANTLRWorks 测试和调试树语法。因此我想解析解析器创建的 AST。使用 ANTLRWorks 测试树语法时，如何指定 AST 作为输入？

PS 我已经研究了的问题/答案有谁知道在 ANTLRWorks 中调试树语法的方法，但它没有回答我的问题。尽管被OP接受，他也发表了类似的评论。

Answer 1

使用 ANTLRWorks 测试树语法时，如何指定 AST 作为输入？

您不需要自己提供 AST，只需提供生成 AST 的解析器即可。

给定生成 AST 的以下语法：

grammar ASTDemo;

options { 
  output=AST;
}

tokens {
  ROOT;
  U_MIN;
}

parse
 : expression EOF -> ^(ROOT expression)
 ;

expression
 : addition
 ;

addition
 : multiplication (('+' | '-')^ multiplication)*
 ;

multiplication
 : unary (('*' | '/')^ unary)*
 ;

unary
 : '-' atom -> ^(U_MIN atom)
 | atom
 ;

atom
 : ID
 | NUMBER
 | '(' expression ')' -> expression
 ;

ID     : ('a'..'z' | 'A'..'Z')+;
NUMBER : '0'..'9'+ ('.' '0'..'9'*)?;
SPACE  : (' ' | '\t' | '\r' | '\n')+ {skip();};

以下是由上述语法生成的 AST 的树语法：

tree grammar ASTDemoWalker;

options {
  output=AST;
  tokenVocab=ASTDemo;
  ASTLabelType=CommonTree;
}

parse
 : ^(ROOT expression)
 ;

expression
 : ^('+' expression expression)
 | ^('-' expression expression)
 | ^('*' expression expression)
 | ^('/' expression expression)
 | ^(U_MIN expression)
 | atom
 ;

atom
 : ID
 | NUMBER
 ;

请务必同时放置 ASTDemo.g 和 ASTDemoWalker.g在同一个文件夹中。在 ANTLRWorks 中打开这两个语法并生成词法分析器和语法分析器。首先按 CTRL+SHIFT+G 来自 ASTDemo.g 的解析器，然后通过打开 < 生成树遍历器code>ASTDemoWalker.g 并按 CTRL+SHIFT+G。

现在，在 ASTDemoWalker.g 编辑器面板中，按 CTRL+D 启动调试器，并将以下源代码粘贴到文本区域中：

42 * ((a + 3) / -3.14)

然后按确定。

现在，您可以逐步完成调试过程，最后，您可以看到解析器生成的 AST：

以及树行者如何走过所说的 AST：

如果您现在在树语法，比如说的^('*'表达式表达式)，您定义^('*'表达式)。如果您再次调试树语法，您将在通过 42 节点后看到它失败：

在 AST 中，42 节点之后还有另一个节点，而树遍历器预计 * 之后只有 1 个单个节点 (42)代码>根节点。

当然，这是一个简单的语法，但即使你熟悉 ANTLR，有时在 @$& 中也会很痛苦。追踪树语法中的错误！ :)