在 X++ 中编程多线程批处理。由于某种原因没有工作？

Question

代码非常简单。从“供应商详细信息”表单中，如果您转到“功能”>“更新 1099”，则用户希望对所有供应商完全开放，而不是手动执行此操作。我修改了基础 VendTax1099Update 类以扩展 RunBaseBatch，然后添加了一堆 parm 方法。我收到此错误，但任务存在吗？我做错了吗？

“无法创建依赖项，因为税务 1099 信息的任务供应商更新不存在。”

我将其设置为“addDependency”，因为当我尝试完全打开它时存在数据库锁。不确定是否有办法解决这些问题。

void run()
{
    BatchHeader         batchHeader;
    VendTax1099Update   vendTax1099Update;
    VendTax1099Update   vendTax1099UpdateOld;
    VendTable           vendTable;
    boolean             first = true;
    ;

    /*
    if (this.isInBatch())
    {
    */
        // Make sure there is a batch header
        if (!batchHeader)
            batchHeader = BatchHeader::construct(this.parmCurrentBatch().BatchJobId);

        while select vendTable
            where vendTable.Tax1099Reports      == true     &&
                  vendTable.Tax1099Box          != ''
        {
            if (Tax1099Fields::exist(vendTable.Tax1099Box))
            {
                vendTax1099Update = new VendTax1099Update();
                vendTax1099Update.parmFromDate(fromDate);
                vendTax1099Update.parmToDate(toDate);
                vendTax1099Update.parmRecalcAmounts(recalcAmounts);
                vendTax1099Update.parmSetAll1099(setAll1099);
                vendTax1099Update.parmBoxFor1099(vendTable.Tax1099Box);
                vendTax1099Update.parmVendorNum(vendTable.AccountNum);

                if (first)
                {
                    batchHeader.addRuntimeTask(vendTax1099Update, this.parmCurrentBatch().RecId);
                    first = false;
                }
                else
                {
                    if (vendTax1099UpdateOld)
                        batchHeader.addDependency(vendTax1099Update, vendTax1099UpdateOld, BatchDependencyStatus::FinishedOrError);
                }

                vendTax1099UpdateOld = vendTax1099Update;
            }
            else
                error (strfmt("Unable to process %1 because %2 was not found in Tax1099Fields", vendTable.AccountNum, vendTable.Tax1099Box));
        }
    /*
    }
    */

    if (batchHeader)
        batchHeader.save();
}

Answer 1

我已经为此绞尽脑汁了几个小时，当然，在发布几分钟后，我在意识到我可以进入batchHeader.addDependency()方法后解决了这个问题。

结果你必须添加任务，然后设置依赖关系。我认为设置依赖关系也同时添加了任务。更正后的代码如下：

            vendTax1099Update.parmBoxFor1099(vendTable.Tax1099Box);
            vendTax1099Update.parmVendorNum(vendTable.AccountNum);

            batchHeader.addRuntimeTask(vendTax1099Update, this.parmCurrentBatch().RecId);

            if (vendTax1099UpdateOld)
                batchHeader.addDependency(vendTax1099Update, vendTax1099UpdateOld, BatchDependencyStatus::FinishedOrError);

            vendTax1099UpdateOld = vendTax1099Update;
        }
        else