在此项目渲染器中创建带有删除按钮的下拉列表

Question

我使用 Flex 4.5，喜欢创建自定义下拉列表。事实上，我想在下拉列表的每一行中显示一个标签和一个删除按钮。 目标是通过单击删除按钮删除该行。 这看起来很简单，但我不知道如何做到这一点。

感谢您的帮助

Answer 1

为此，您必须跳过一些步骤，因为 DropDownList 会阻止触发来自 ItemRenderer 内的对象的任何 MouseEvent.CLICK。

首先要做的事情是：您需要一个自定义事件才能使其工作。带有您的物品或至少其索引的一个。例如：

public class ItemEvent extends Event {
    public static const REMOVE:String = "itemRemove";

    public var item:MyClass;

    public function ItemEvent(type:String, item:MyClass, 
                              bubbles:Boolean=false, 
                              cancelable:Boolean=false) {
        super(type, bubbles, cancelable);
        this.item = item;
    }

    override public function clone():Event {
        return new ItemEvent(type, item, bubbles, cancelable);
    }

}

然后您创建一个带有“删除”按钮的自定义 ItemRenderer，该按钮将调度此事件。

<s:ItemRenderer xmlns:fx="http://ns.adobe.com/mxml/2009" 
                xmlns:s="library://ns.adobe.com/flex/spark">

    <fx:Script>
        <![CDATA[
            private function remove():void {
                owner.dispatchEvent(
                    new ItemEvent(ItemEvent.REMOVE, data as MyClass)
                );
            }
        ]]>
    </fx:Script>

    <s:Label id="labelDisplay" verticalCenter="0" left="10" />

    <s:Button verticalCenter="0" right="10" width="16" height="16"
              mouseDown="remove()" />

</s:ItemRenderer>

这里重要的是您捕获按钮的 MOUSE_DOWN 事件，因为它的 CLICK 事件不会触发（如前所述）。 ItemRenderer 的 owner 属性引用其子级的 List。

现在是最后一块拼图了。这是带有自定义 ItemRenderer 的 DropDownList：

<s:DropDownList id="myDropDownList" dataProvider="{dp}"
                itemRenderer="MyItemRenderer" />

以下是您如何侦听该自定义事件并删除所选项目：

myDropDownList.addEventListener(ItemEvent.REMOVE, removeSelectedItem);

private function removeSelectedItem(event:ItemEvent):void {
    var items:IList = myDropDownList.dataProvider;
    var index:int = items.getItemIndex(event.item);
    items.removeItemAt(index);
}

因为我们捕获了 MOUSE_DOWN 而不是 CLICK，所以 myDropDownList.selectedIndex 属性仍将位于先前所选的项目处（如果没有选择，则为 -1）。这就是我们需要自定义事件的原因，因为没有其他方法可以知道您要删除哪个项目。