Delphi 无边框和无标题应用程序

Question

我愿意使用以下代码在Delphi XE2无边框和无标题中设计一个应用程序：

  BorderIcons = []
  BorderStyle = bsNone

但问题是任务栏上的应用程序右键单击没有菜单，就像上图所示。然后我在 FormShow 事件上尝试了以下代码，但还有另一个问题。在左侧和左下侧创建一个边框。代码是：

procedure TForm1.FormShow(Sender: TObject);
var
  r: TRect;
begin
  r := ClientRect;
  OffsetRect(r, 0, GetSystemMetrics(SM_CYCAPTION));
  OffsetRect(r, GetSystemMetrics(SM_CXFRAME), GetSystemMetrics(SM_CYFRAME));
  SetWindowRgn(Handle,
  CreateRectRgn(
  r.Left, r.Top,
  ClientWidth + r.Left, ClientHeight + r.Top), True);

end;

请帮助我。

Answer 1

简单的解决方案就是首先不要删除系统菜单。请注意，系统菜单是应用程序中缺少的菜单的正式名称。

让您的 .dfm 文件如下所示：

BorderIcons = [biSystemMenu]
BorderStyle = bsNone

去掉 FormShow 代码 - 它是不需要。

好吧，看起来我的实验中的一些零散代码让我感到困惑。这是有效的。

完全按照您最初在 .dfm 表单中所做的操作：

BorderIcons = []
BorderStyle = bsNone

然后使用 CreateParams 添加回系统菜单：

TForm1 = class(TForm)
protected
  procedure CreateParams(var Params: TCreateParams); override;
end;
...
procedure TForm1.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.Style := Params.Style or WS_SYSMENU;
end;

Answer 2

procedure TForm1.FormCreate(Sender: TObject);
begin
  BorderStyle := bsNone;
  SetWindowLong(Handle, GWL_STYLE, 
      WS_POPUP or WS_CLIPSIBLINGS or WS_CLIPCHILDREN or WS_SYSMENU);
  SetWindowLong(Handle, GWL_EXSTYLE, WS_EX_CONTROLPARENT or WS_EX_APPWINDOW);
end;

使用此解决方案，您不需要 OnShow 处理程序中的代码。

上面的代码可以随时调用（不仅仅是在 OnCreate 中），它可以用于改变例如正在运行的表单的行为（只需将 WS_VISIBLE 包含到窗口样式中）如果表单已经可见）。

如果您希望该行为在表单的生命周期内有效，最好在重写的 CreateParams 中设置标志（其中表单样式由 VCL 应用）。这还将考虑可能的表单重新创建。对于此解决方案，不要从 OI 设置任何表单属性，所有标志都在代码中显式设置：

type
  TForm1 = class(TForm)
    ..
  protected
    procedure CreateParams(var Params: TCreateParams); override;

..

procedure TForm1.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.Style := WS_POPUP or WS_CLIPSIBLINGS or WS_CLIPCHILDREN or WS_SYSMENU;
  Params.ExStyle := WS_EX_CONTROLPARENT or WS_EX_APPWINDOW;
end;

Answer 3

通过简单地接管整个窗口的绘制，您可以拥有一个看起来没有标题栏或标准标题的窗口：

创建一个新的空应用程序。将此代码用于您的表单：

unit ncUnit1;

interface

// XE2 uses clause
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,      
  Vcl.Graphics,   Vcl.Controls, Vcl.Forms, Vcl.Dialogs;
// If you're not using XE2 take out the prefixes (WinApi, Vcl, System, etc)

type
  TForm1 = class(TForm)
  private
    { Private declarations }
  public
    { Public declarations }
  protected
    procedure WMNCPaint(var Message: TWMNCPaint); message WM_NCPAINT;
    procedure SolidColorNcPaint(solidColor,frameColor:TColor);
    procedure Resizing(State: TWindowState); override;


  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TForm1 }

procedure TForm1.WMNCPaint(var Message: TWMNCPaint);
begin
  SolidColorNcPaint(clBtnFace,clBtnFace);
end;

procedure TForm1.Resizing(State: TWindowState);
begin
  inherited;
  PostMessage(Self.Handle,WM_NCPAINT,0,0); {force initial paint}
end;

procedure TForm1.SolidColorNcPaint(solidColor,frameColor:TColor);
var
 aBorder:Integer;
 ahdc : HDC;
begin
 aBorder := GetSystemMetrics(SM_CYSIZEFRAME);
 canvas.Lock;
 ahdc := GetWindowDC(Handle);
 canvas.Handle := ahdc;
 ExcludeClipRect(canvas.Handle, aBorder, 0, Width-aBorder, Height - aBorder) ;
 Canvas.Brush.Style := bsSolid;
 Canvas.Brush.Color := frameColor;
 Canvas.Pen.Color := solidColor;
 Canvas.Rectangle( 0,0, Width,Height);
 ReleaseDC(Self.Handle, ahdc);
 canvas.Handle := 0;
 canvas.Unlock;
end;


end.

您在上面看到的代码仅足以在窗口的非客户区域上重绘纯色，而不能完全删除它。根据您想要的自定义窗口的样式，您应该在表单上呈现您想要的任何内容。如果您不需要关闭按钮，请删除关闭按钮，如果您不需要调整大小行为，请删除调整大小行为。如果您设置 FormStyle=fsDialog 加上上面的代码，您将获得一个具有完整的自定义绘制标题区域的窗口（您可以在其中放入任何您想要的内容）。如果您实际上根本不希望标题区域存在，您也可以修改上面的代码来实现这一点。

Answer 4

您可以按照 David 所说的操作和/或也看看：
SetWindowRgn API。

如果您只使用 SetWindowRgn，则不必删除 TForm 的边框，只需在其下方创建一个矩形即可。