Delphi onshow 主窗体/模态窗体

Question

我有一个项目，有一个主窗体和一些其他窗体。 当应用程序加载时，它需要执行一些任务并在主窗体顶部以模式形式显示结果。 我遇到的问题是，如果我调用函数来执行任务/创建并在主窗体 onshow 事件中显示模态窗体，则模态窗体会出现，但主窗体不会出现，直到模态窗体关闭，即我期望发生什么。为了解决这个问题，我在主窗体中添加了一个计时器，并在主窗体 onshow 事件上启动它，计时器调用函数来执行任务/创建并显示模式窗体。所以现在主窗体出现在模态窗体之前。

然而，我不认为这是最好的解决方案，并且想知道是否有人可以提供更好的解决方案。

我正在使用 Delphi 7

科林

Answer 1

一个常用的选项是在表单的 OnShow 中向自己发布一条消息。像这样：

const
  WM_SHOWMYOTHERFORM = WM_USER + 0;

type
  TMyMainForm = class(TForm)
    procedure FormShow(Sender: TObject);
  protected
    procedure WMShowMyOtherForm(var Message: TMessage); message WM_SHOWMYOTHERFORM;
  end;

...


procedure TMyMainForm.FormShow(Sender: TObject);
begin
  PostMessage(Handle, WM_SHOWMYOTHERFORM, 0, 0);
end;

procedure TMyMainForm.WMShowMyOtherForm(var Message: TMessage);
begin
  inherited;
  with TMyOtherForm.Create(nil) do begin
    try
      ShowModal;
    finally
      Free;
    end;
  end;
end;

Answer 2

为什么不像这样使用 MainForm OnActivate 事件呢？

procedure TMyMainForm.FormActivate(Sender: TObject);
begin
  //Only execute this event once ...
  OnActivate := nil;

  //and then using the code David Heffernan offered ...
  with TMyOtherForm.Create(nil) do begin
    try
      ShowModal;
    finally
      Free;
    end;
end;

将事件设置为 nil 将确保此代码仅在启动时运行一次。

Answer 3

OnShow 事件在调用 Windows API 函数 ShowWindow 之前立即触发。正是对 ShowWindow 的调用实际上导致窗口出现在屏幕上。

因此，理想情况下，您需要在调用 ShowWindow 后立即运行某些内容。事实证明，驱动这一切的 VCL 代码位于 CM_SHOWINGCHANGED 的 TCustomForm 消息处理程序内。该消息处理程序触发 OnShow 事件，然后调用 ShowWindow。因此，一个很好的解决方案是在 CM_SHOWINGCHANGED 处理程序运行后立即显示模态表单。像这样：

type
  TMyMainForm = class(TForm)
  private
    FMyOtherFormHasBeenShown: Boolean;
  protected
    procedure CMShowingChanged(var Message: TMessage); message CM_SHOWINGCHANGED;
  end;

.....

procedure TMyMainForm.CMShowingChanged(var Message: TMessage);
begin
  inherited;
  if Showing and not FMyOtherFormHasBeenShown then begin
    FMyOtherFormHasBeenShown := True;
    with TMyOtherForm.Create(nil) do begin
      try
        ShowModal;
      finally
        Free;
      end;
    end;
  end;
end;