如何在 Mathematica 中基于部分字符串匹配进行选择

Question

假设我有一个看起来像这样的矩阵：

{{foobar, 77},{faabar, 81},{foobur, 22},{faabaa, 8},
{faabian, 88},{foobar, 27}, {fiijii, 52}}

和一个像这样的列表：

{foo, faa}

现在我想根据列表中字符串的部分匹配来添加矩阵中每一行的数字，以便我最终得到这个：

{{foo, 126},{faa, 177}}

我假设我需要映射一个 Select 命令，但我不太确定如何做到这一点并仅匹配部分字符串。有人可以帮助我吗？现在我的真实矩阵大约有 150 万行，所以不太慢的东西会具有附加值。

Answer 1

这是一个起点：

data={{"foobar",77},{"faabar",81},{"foobur",22},{"faabaa",8},{"faabian",88},{"foobar",27},{"fiijii",52}};

{str,vals}=Transpose[data];
vals=Developer`ToPackedArray[vals];
findValPos[str_List,strPat_String]:=
    Flatten[Developer`ToPackedArray[
         Position[StringPosition[str,strPat],Except[{}],{1},Heads->False]]]

Total[vals[[findValPos[str,"faa"]]]]

Answer 2

这是另一种方法。它相当快，而且也简洁。

data =
 {{"foobar", 77},
  {"faabar", 81},
  {"foobur", 22},
  {"faabaa", 8},
  {"faabian", 88},
  {"foobar", 27},
  {"fiijii", 52}};

match = {"foo", "faa"};

f = {#2, Tr @ Pick[#[[All, 2]], StringMatchQ[#[[All, 1]], #2 <> "*"]]} &;

f[data, #]& /@ match

{{"foo", 126}, {"faa", 177}}

---

您可以使用 ruebenko 的预处理来提高速度。
这大约是他在我的系统上的方法的两倍：

{str, vals} = Transpose[data];
vals = Developer`ToPackedArray[vals];

f2 = {#, Tr @ Pick[vals, StringMatchQ[str, "*" <> # <> "*"]]} &;

f2 /@ match

请注意，在这个版本中，我测试了不在开头的子字符串，以匹配 ruebenko 的输出。如果您只想在字符串的开头匹配（这就是我在第一个函数中假设的），那么它会更快。

Answer 3

使数据

mat = {{"foobar", 77},
   {"faabar", 81},
   {"foobur", 22},
   {"faabaa", 8},
   {"faabian", 88},
   {"foobar", 27},
   {"fiijii", 52}};
lst = {"foo", "faa"};

现在

r1 = Select[mat, StringMatchQ[lst[[1]], StringTake[#[[1]], 3]] &];
r2 = Select[mat, StringMatchQ[lst[[2]], StringTake[#[[1]], 3]] &];
{{lst[[1]], Total@r1[[All, 2]]}, {lst[[2]], Total@r2[[All, 2]]}}

选择给定

{{"foo", 126}, {"faa", 177}}

如果可以的话，我将尝试使其更加实用/通用...

编辑(1)

下面的内容使其更加通用。 （使用与上面相同的数据）：

foo[mat_, lst_] := Select[mat, StringMatchQ[lst, StringTake[#[[1]], 3]] &]
r = Map[foo[mat, #] &, lst];
MapThread[ {#1, Total[#2[[All, 2]]]} &, {lst, r}]

给出

{{"foo", 126}, {"faa", 177}}

所以现在如果将 lst 更改为 3 项而不是 2 项，上面的相同代码将起作用：

lst = {"foo", "faa", "fii"};

Answer 4

怎么样：

list = {{"foobar", 77}, {"faabar", 81}, {"foobur", 22}, {"faabaa", 
    8}, {"faabian", 88}, {"foobar", 27}, {"fiijii", 52}};

t = StringTake[#[[1]], 3] &;

{t[#[[1]]], Total[#[[All, 2]]]} & /@ SplitBy[SortBy[list, t], t]

{{"faa", 177}, {"fii", 52}, {"foo", 126}}

我确信我读过一篇文章，也许在这里，其中有人描述了一个有效组合排序和拆分的函数，但我不记得了。也许其他人知道的话可以添加评论。

编辑

好吧，必须是就寝时间了——我怎么会忘记 Gatherby

{t[#[[1]]], Total[#[[All, 2]]]} & /@ GatherBy[list, t]

{{"foo", 126}, {"faa", 177}, {"fii", 52}}

请注意，对于 140 万对的虚拟列表，这需要几秒钟，所以不完全是一个超级快速的方法。