如何展平键值对的哈希值？

Question

我想与大家分享我创建的一个函数，看看如何优化它，或者是否有更好的方法来做到这一点。

  sub flatten{
    my($ref,$delim,$item_delim,$array,$str) = @_;

    die("Required Hash Reference") unless isHash($ref);

    $delim = $delim ? $delim  :'_';

      #dump into array hash vals #simplified
      if(!$item_delim){
        @{$array} = %{$ref};
      }else{
        my($keys,$values);

        $keys = getKeys($ref);
        $values = getValues($ref);

        #item strings
        if($#$keys > 0 && $#$values > 0){
          #fix for issue where value[n] is empty
          @{$array}= map{ (defined $$values[ $_ ]) ? $$keys[ $_ ].$item_delim.$$values[ $_ ] : $$keys[ $_ ].$item_delim } 0 .. int($#$keys);
        }else{
         log "No Values to flatten";
         return '';
        }
      }

    $str = join($delim,@{$array});
    return $str;
  }

这里有什么我应该注意的优化点吗？

基本上我想从

$HASH => {

 key1 => 'val1',
 key2 => 'val2',
 key3 => 'val3',

}

$STRING= key1=val1&key2=val2 ...

UPDATED

没有模块的解决方案是首选我真的只是想知道如何有效压平哈希！

请注意，这里的一些函数只是简单的包装函数，它们按照它们的说明执行操作。 isHash getKeys...不用注意那些！

Answer 1

use URI::Escape;
my $str=join '&',map {uri_escape($_).'='.uri_escape($QUERY_STRING->{$_})} grep {defined $QUERY_STRING->{$_}} keys %$QUERY_STRING;

我认为这应该有效！

Answer 2

我在您的问题中看不到任何内容，这意味着您的子例程需要比以下内容更复杂：

sub flatten {
  my ($hash, $delim, $item_delim) = @_;

  $delim //= '&',
  $item_delim //= '=';

  return join $delim, map { "$_$item_delim$hash->{$_}" } keys %$hash;
}

更新：在这里获得一些反对票。我假设人们会反对我没有对任何内容进行 URI 编码这一事实。我只是指出，原始问题中没有任何内容表明我们正在构建 URI。如果我知道我们是这样，那么我肯定会使用适当的模块。

这就是为什么我说“我在你的问题中看不到任何内容......”。

Answer 3

没有模块：

my $hashref = {    
  key1 => 'val1',
  key2 => 'val2',
  key3 => 'val3',  
};

sub encode {
  my $str = shift;
  $str =~ s/([^A-Za-z0-9\.\/\_\-])/sprintf("%%%02X", ord($1))/seg;
  return $str;
}

my $str = join '&' => map { encode($_).'='.encode($hashref->{$_}) } grep { defined $hashref->{$_} } keys %$hashref;

结果：

key2=val2&key1=val1&key3=val3

Answer 4

一种方便的方法是使用 URI 的 query_form 工具。

use URI;

my $uri = URI->new("", "http"); # We don't actually care about the path...
$uri->query_form(%params);
my $query_string = $uri->query;

另一种更手动的方法是仅使用 URI::Escape、映射和连接。